উইন্ডোজ অফলাইনে চলমান কম্পিউটারে (ইন্টারনেট সংযোগ ব্যতীত) কাজ করার সময়, কমান্ড-লাইনের মাধ্যমে উপলভ্য সিএমডি কমান্ডের (ব্যবহার সহ) একটি তালিকা পাওয়া / উত্পন্ন করা সম্ভব ?
উইন্ডোজ অফলাইনে চলমান কম্পিউটারে (ইন্টারনেট সংযোগ ব্যতীত) কাজ করার সময়, কমান্ড-লাইনের মাধ্যমে উপলভ্য সিএমডি কমান্ডের (ব্যবহার সহ) একটি তালিকা পাওয়া / উত্পন্ন করা সম্ভব ?
উত্তর:
আদেশের তালিকার জন্য:
help
এবং একটি নির্দিষ্ট কমান্ড সম্পর্কে বিশদ জন্য:
help <command>
অথবা
<command> /?
উদাহরণ স্বরূপ:
help xcopy
xcopy /?
ping, arp, nslookup? দেখে মনে হচ্ছে যে helpকেবলমাত্র উইন্ডোজ কমান্ডগুলির তালিকা তৈরি করে না নেটওয়ার্কিং কমান্ডগুলি।
windows\system32ফোল্ডারে প্রোগ্রামগুলি যা আমি বিশ্বাস করি যে প্রোগ্রাম / কমান্ডগুলি সমাধান করার সময় এটি দেখতে পেত । আপনার তালিকার জন্য আপনি সেখানে এক্সদের সন্ধান করতে পারেন। অলিভার এর উত্তর দেখুন।
আপনি মাইক্রোসফ্ট কমান্ড-লাইন রেফারেন্স এজেড এ একটি অফিসিয়াল তালিকা পেতে পারেন । এর পাশাপাশি...
আপনার প্রশ্নের সরাসরি উত্তর দিতে, আমি একটি স্ক্রিপ্ট তৈরি করেছি .exeযাতে আপনি কার্যকর করতে পারেন এমন সমস্ত ফাইলকে কেবল তালিকাবদ্ধ করে (কারণ সেগুলি আপনার অবস্থিত PATH)। ডিফল্টরূপে, এটি কেবল তাদের মধ্যে তালিকাবদ্ধ করে %WINDIR%(যদি আপনি এটি চালনা না করেন --all)।
স্ক্রিপ্টের আগের পুনরাবৃত্তিতে আমি প্রতিটি কমান্ড দিয়ে শুরু করেছিলাম /?যা খুব খারাপ ধারণা। প্রতিটি অ্যাপ্লিকেশন PATHসেই প্যারামিটারটি বোঝে না। কিছু সাহায্য প্রিন্ট না করে কেবল শুরু এবং চলমান থাকবে। যাতে দ্রুত প্রচুর সংস্থান খায়।
@SETLOCAL ENABLEEXTENSIONS
@ECHO OFF
IF "%1"=="--all" (
SET LIST_ALL=TRUE
)
CALL :printPath "%PATH%"
:printPath
FOR /F "tokens=1,* delims=;" %%A IN ("%~1") DO (
IF EXIST "%%A" (
PUSHD "%%A"
FOR %%F IN (*.exe) DO (
ECHO.%%~dnpfF | FINDSTR /C:"%WINDIR%" 1> NUL
IF ERRORLEVEL 1 (
IF "%LIST_ALL%"=="TRUE" ECHO.%%~dnpfF
) ELSE (
ECHO.%%~dnpfF
)
)
POPD
) ELSE (
REM ECHO Skipping non-existent folder '%%A'
)
CALL :printPath "%%~B"
)
ENDLOCAL
সুতরাং, সেখানে। এটি আপনাকে সমস্ত উপলব্ধ কমান্ড এবং তাদের পরামিতিগুলির একটি তালিকা দেয় gives আপনি ইতিমধ্যে আশা করতে পারেন, এটি কল্পনা করা হিসাবে দরকারী হিসাবে।
এখানে কি সত্যিই গুরুত্বপূর্ণ!
বেশি আকর্ষণীয় .exeআপনার ফাইল PATHহয় cmd.exeবিল্ট-ইন। লাইক IF, FORএবং SET। আমার কাছে বিল্ট-ইনগুলির একটি সম্পূর্ণ তালিকা নেই তবে আপনি বেশিরভাগটি চালিয়ে দেখতে পারেন cmd.exe /?:
DEL or ERASE
COLOR
CD or CHDIR
MD or MKDIR
PROMPT
PUSHD
POPD
SET
SETLOCAL
ENDLOCAL
IF
FOR
CALL
SHIFT
GOTO
START (also includes changes to external command invocation)
ASSOC
FTYPE
যদিও, সেই সময়ে সহায়তা কমান্ড এক্সটেনশানগুলি উল্লেখ করে , তাই তালিকাটি অসম্পূর্ণ হতে পারে। আসুন কিছু বিল্ট-ইনগুলি ঘনিষ্ঠভাবে দেখি:
FORকমান্ডের জন্য ডকুমেন্টেশনগুলি আপনাকে যে সমস্ত ক্রেজি প্যারামিটারে যেতে পারে তার তালিকা করে FOR। আপনি লুপগুলি সম্পর্কিত যে কোনও কিছু লিখতে চাইলে এটি হ'ল গ-টু ইউটিলিটি ।
এই ডকুমেন্টেশনে পাগল "টিল্ড নোটেশন" এর ব্যাখ্যাও রয়েছে:
In addition, substitution of FOR variable references has been enhanced
You can now use the following optional syntax:
%~I - expands %I removing any surrounding quotes (")
%~fI - expands %I to a fully qualified path name
%~dI - expands %I to a drive letter only
%~pI - expands %I to a path only
%~nI - expands %I to a file name only
%~xI - expands %I to a file extension only
%~sI - expanded path contains short names only
%~aI - expands %I to file attributes of file
%~tI - expands %I to date/time of file
%~zI - expands %I to size of file
%~$PATH:I - searches the directories listed in the PATH
environment variable and expands %I to the
fully qualified name of the first one found.
If the environment variable name is not
defined or the file is not found by the
search, then this modifier expands to the
empty string
The modifiers can be combined to get compound results:
%~dpI - expands %I to a drive letter and path only
%~nxI - expands %I to a file name and extension only
%~fsI - expands %I to a full path name with short names only
%~dp$PATH:I - searches the directories listed in the PATH
environment variable for %I and expands to the
drive letter and path of the first one found.
%~ftzaI - expands %I to a DIR like output line
IFশাখা প্রশাখার জন্য আদেশ । আপনার এই পৃষ্ঠার প্রয়োজন হবে কারণ এটি তুলনা অপারেটরগুলির তালিকা করে:
If Command Extensions are enabled IF changes as follows:
IF [/I] string1 compare-op string2 command
IF CMDEXTVERSION number command
IF DEFINED variable command
where compare-op may be one of:
EQU - equal
NEQ - not equal
LSS - less than
LEQ - less than or equal
GTR - greater than
GEQ - greater than or equal
SET আপনাকে ভেরিয়েবলগুলিতে বিভিন্ন ধরণের অপারেশন করতে দেয় perform
The /A switch specifies that the string to the right of the equal sign
is a numerical expression that is evaluated. The expression evaluator
is pretty simple and supports the following operations, in decreasing
order of precedence:
() - grouping
! ~ - - unary operators
* / % - arithmetic operators
+ - - arithmetic operators
<< >> - logical shift
& - bitwise and
^ - bitwise exclusive or
| - bitwise or
= *= /= %= += -= - assignment
&= ^= |= <<= >>=
, - expression separator
এটি উপরের উল্লিখিত "টিল্ড স্বরলিপি" এর মাধ্যমে স্ট্রিং ম্যানিপুলেশনের অনুমতি দেয়
C:\Windows\System32। আমি ধরে নিলাম যেPATH
ARP.EXEযদিও তালিকাবদ্ধ । আপনি যখন আপনার স্ক্রিপ্টটি কার্যকর করবেন তখন আমি যে আদেশগুলি উল্লেখ করেছি তা কি আপনি দেখতে পাচ্ছেন?
PATHএমন কোনও ফোল্ডার থাকে যা বিদ্যমান নেই। যার ফলে স্ক্রিপ্টটি ভেঙে যায়। এটা কি সমস্যা? আমি একটি স্থির উপর কাজ করছি।
PATH: ডি
ডাস্টিপস.কম ( ক্রিয়েটডসকম্যান্ডইন্ডেক্স.ব্যাট ) এ ব্যাচ স্ক্রিপ্ট উপলব্ধ আছে যা "কমান্ডনাম / /" এর মাধ্যমে উত্পন্ন আউটপুট সহ সিস্টেমে উপলব্ধ ডস কমান্ডের সম্পূর্ণ তালিকা সহ একটি এইচটিএমএল ফাইল উত্পন্ন করে?
আমি এটি নীচে প্রতিবেদন করছি যেহেতু ডাস্টিপস.কম এ সময়ে ডিবি লোড সম্পর্কিত সমস্যা আছে বলে মনে হচ্ছে এবং তাদের ওয়েবসাইট মাঝে মাঝে কাজ করে।
@ECHO OFF
REM.-- Prepare the Command Processor
SETLOCAL ENABLEEXTENSIONS
REM --
REM -- Copyright note
REM -- This script is provided as is. No waranty is made, whatso ever.
REM -- You may use and modify the script as you like, but keep the version history with
REM -- recognition to http://www.dostips.com in it.
REM --
REM Version History:
REM XX.XXX YYYYMMDD Author Description
SET "version=01.000" &:20051201 p.h. initial version, origin http://www.dostips.com
SET "version=01.001" &:20060122 p.h. Fix missing exclamation marks in documentation (http://www.dostips.com)
SET "version=01.002" &:20060218 p.h. replaced TEXTAREA with PRE XMP (http://www.dostips.com)
SET "version=01.003" &:20060218 p.h. php embedding (http://www.dostips.com)
SET "version=01.004" &:20060723 p.h. fix page links for FireFox (http://www.dostips.com)
SET "version=01.005" &:20061015 p.h. invoke HELP via '"call" help', allows overriding help command with a help.bat file (http://www.dostips.com)
SET "version=01.006" &:20061015 p.h. cleanup progress indicator (http://www.dostips.com)
SET "version=01.007" &:20080316 p.h. use codepage 1252 to support european users (http://www.dostips.com)
SET "version=02.000" &:20080316 p.h. use FOR command to generate HTML, avoids most escape characters (http://www.dostips.com)
SET "version=02.000" &:20100201 p.h. now using css and xhtml
REM !! For a new version entry, copy the last entry down and modify Date, Author and Description
SET "version=%version: =%"
for /f "delims=: tokens=2" %%a in ('chcp') do set "restore_codepage=%%a"
chcp 1252>NUL
set "z=%~dpn0.htm"
rem echo.^<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.0 Transitional//EN"^> >"%z%"
echo.^<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd"^> >"%z%"
set "title=DOS Command Index"
for /f "tokens=*" %%a in ('ver') do set "winver=%%a"
echo.Creating the header ...
for %%A in (
"<html lang='en-US' xml:lang='en-US' xmlns='http://www.w3.org/1999/xhtml'>"
"<head>"
"<style type='text/css'>"
" h1 {text-align:center;}"
" h2 {text-align:center;}"
" table.center {margin-left: auto;margin-right: auto;}"
" td {text-align:left;}"
" div.center {text-align:center;}"
" div.sourcebatch {background: #DDDDDD;}"
" div.helptext {background: #F8F8FF;}"
" div.top {float: right;}"
"</style>"
"<title>%title%</title>"
"<meta http-equiv='Content-Type' content='text/html; charset=ISO-8859-1' />"
"</head>"
"<body bgcolor='#FFFFCC'>"
"<font color='darkblue'>"
"<h1>%title%</h1>"
"<div class='center'>"
"<table class='center' border='1' cellspacing='1' cellpadding='3'>"
" <tr><td>Windows Version</td><td>:</td><td>%winver%</td></tr>"
" <tr><td>Document Source</td><td>:</td><td>"
" <a href='http://www.dostips.com/'><b>http://www.dostips.com</a><br />"
" <a href='http://www.dostips.com/%~n0.php'><b>http://www.dostips.com/%~nx0.php</a>"
" </td></tr>"
" <tr><td>Created by</td><td>:</td><td><a href='http://www.dostips.com/%~nx0'>"
" <b>%~nx0</b></a><br /><a href='#%~n0'><b>Source Code below</b></a></td></tr>"
"</table>"
"</div>"
"<br /><br />"
"<table class='center'>"
) do echo.%%~A>>"%z%"
echo.Creating the index ...
set /a cnt=0
for /f "tokens=1,*" %%a in ('"help|findstr /v /b /c:" " /c:"For more""') do (
for %%A in (
" <tr><td><a href='#%%a'>%%a</a></td><td>%%b</td></tr>"
) do echo.%%~A>>"%z%"
set /a cnt+=1
)
for %%A in (
"</table>"
"<br /><br />"
) do echo.%%~A>>"%z%"
echo.Extracting HELP text ...
call:initProgress cnt
for /f %%a in ('"help|findstr /v /b /c:" " /c:"For more""') do (
echo.Processing %%a
for %%A in (
"<div class='top'><a href='#'>TOP</a></div>"
"<h2><a name='%%a'>%%a</a></h2>"
"<div class='helptext'><pre><xmp>"
) do echo.%%~A>>"%z%"
call help %%a >>"%z%" 2>&1
echo ^</xmp^> >>"%z%"
for %%A in (
"</pre></div>"
) do echo.%%~A>>"%z%"
call:tickProgress
)
echo.Injecting source script ...
for %%A in (
""
"<br /><br />"
"<div class='center'>"
"<div class='top'><a href='#'>TOP</a></div>"
"<a name='%~n0'><h2>DOS Batch Script Source that created this Document</h2></a>"
"This %title% has been created automatically by the following DOS batch script:"
"<br /><br />"
"</div>"
"<div class='sourcebatch'><pre><xmp>"
) do echo.%%~A>>"%z%"
type "%~f0" >>"%z%"
echo.Creating the footer ...
echo ^</xmp^> >>"%z%"
for %%A in (
"</pre></div>"
""
"</font>"
"</body>"
"</html>"
) do echo.%%~A>>"%z%"
chcp %restore_codepage%>NUL
explorer "%z%"
:SKIP
REM.-- End of application
FOR /l %%a in (5,-1,1) do (TITLE %title% -- closing in %%as&ping -n 2 -w 1 127.0.0.1>NUL)
TITLE Press any key to close the application&ECHO.&GOTO:EOF
::-----------------------------------------------------------
::helper functions follow below here
::-----------------------------------------------------------
:initProgress -- initialize an internal progress counter and display the progress in percent
:: -- %~1: in - progress counter maximum, equal to 100 percent
:: -- %~2: in - title string formatter, default is '[P] completed.'
set /a "ProgressCnt=-1"
set /a "ProgressMax=%~1"
set "ProgressFormat=%~2"
if "%ProgressFormat%"=="" set "ProgressFormat=[PPPP]"
set "ProgressFormat=%ProgressFormat:[PPPP]=[P] completed.%"
call :tickProgress
GOTO:EOF
:tickProgress -- display the next progress tick
set /a "ProgressCnt+=1"
SETLOCAL
set /a "per=100*ProgressCnt/ProgressMax"
set "per=%per%%%"
call title %%ProgressFormat:[P]=%per%%%
GOTO:EOF
Processing SCযদিও এটি আমার জন্য বন্ধ হয়ে যায় । তবে মনে হচ্ছে এটি কেবল কিছু ইনপুটটির জন্য অপেক্ষা করছে। সুতরাং Enterএটি টিপুন এটি শেষ করুন :)
helpকমান্ড শো (যা সহজ চালানো)। তবুও, ইনপুটটির জন্য ধন্যবাদ, এটি খুব দরকারী। অলিভারসালজবার্গ এটি আমার জন্যও থেমে আছে।
আপনি অফলাইন সমাধানটি সন্ধান করছেন ঠিক এটি নয় (ওয়েবপেজ খোলার জন্য আপনার ইন্টারনেট সংযোগের প্রয়োজন) তবে এটি একটি খুব দরকারী সরঞ্জাম এবং সিএমডি কমান্ডের রেফারেন্স:
আমি জানি আপনি ঠিক যা চাইছেন তা নয়, তবে আপনি কমান্ড প্রম্পটের পরিবর্তে পাওয়ারশেল শিখতে শুরু করতে পারেন। মাইক্রোসফ্ট পাওয়ারশেলের জন্য কমান্ড প্রম্পট তৈরি করার চেষ্টা করছে যাতে এটি শেখা ভাল দক্ষতা হবে।
আপনি যদি পাওয়ারশেল এ থাকেন তবে কমান্ডটি Get-Commandসমস্ত কমান্ডের তালিকা দেবে যা বর্তমানে সমস্ত লোড হওয়া মডিউল থেকে চালানো যেতে পারে। এটি এমন আউটপুট তৈরি করবে যা দেখতে এরকম দেখাচ্ছে:
CommandType Name Definition
----------- ---- ----------
Cmdlet Add-Content Add-Content [-Path] <String[...
Cmdlet Add-History Add-History [[-InputObject] ...
Cmdlet Add-Member Add-Member [-MemberType] <PS...
Cmdlet Add-PSSnapin Add-PSSnapin [-Name] <String...
Cmdlet Clear-Content Clear-Content [-Path] <Strin...
xcopy /?কমান্ড সম্পর্কে তথ্য পেতে ব্যবহার করতে পারেন । :)