আউটলুক 2010 এ, বর্তমানে স্নুজিংয়ের অনুস্মারকগুলি দেখার কোনও উপায় আছে কি?

Question

আউটলুক ২০১০-এ কোনও উপায় আছে যা বর্তমানে स्नুজড আইটেমগুলির একটি তালিকা টানতে পারে? উদাহরণস্বরূপ, আসুন দুই সপ্তাহের মধ্যে আমি শুক্রবার পরের সোমবার একটি গুরুত্বপূর্ণ মধ্যাহ্নভোজ বৈঠকের জন্য পপ আপ করার জন্য একটি অনুস্মারক রেখেছি (আমি উইকএন্ডের আগে সোমবারের কাজগুলি স্মরণ করিয়ে দিতে চাই)। শুক্রবারে যখন অনুস্মারকটি পপ আপ হয়, আমি এটিকে তিন দিনের জন্য স্নুজ করি যাতে এটি সোমবার মধ্যাহ্নভোজের আগেই আবার পপ আপ হয়। তারপরে সোমবার চারদিকে ঘুরছে এবং আমার স্মৃতিটি ঝাপসা হয়ে গেছে এবং আমি কিছুটা ভৌতিক হয়েছি যে শুক্রবারে আমি সঠিকভাবে স্মরণ করিয়ে দেওয়ার পরিবর্তে স্মরণটিকে বাতিল করে দিয়েছিলাম accident আমি এখনও আমার ক্যালেন্ডারে আসল অ্যাপয়েন্টমেন্ট দেখতে পাচ্ছি, তবে আমার নিশ্চিত হওয়া দরকার যে আমি যখন রিমাইন্ডারটি আশা করি তখন এটি পপ আপ করে যাব যাতে আমার সভাটি মিস না হয়।

আউটলুক ২০১০-এ কোনও উপায় আছে যা বর্তমানে স্মরণ করিয়ে দেওয়া অনুস্মারকগুলির তালিকা টানতে পারে? এটি সেই ক্ষেত্রেও সহায়ক হবে যেখানে আমি কোনও কাজ শেষ করি যার অনুস্মারকটি আমি পরে স্নোজ করেছিলাম এবং আমি এখন স্নুজযুক্ত অনুস্মারকটি টেনে এনে এটি বাতিল করতে চাই।

Answer 1

Sub SnoozedReminders()

' http://www.jpsoftwaretech.com/check-your-outlook-reminders-in-vba/

Dim MyReminder As Outlook.Reminder
Dim MyReminders As Outlook.Reminders
Dim Report As String
Dim i As Long

Set MyReminders = Outlook.Reminders

i = 0

For Each MyReminder In MyReminders

    If HasReminderFired(MyReminder) = True Then
        i = i + 1
        Report = Report & i & ": " & MyReminder.Caption & vbCr & _
            "     Snoozed to " & MyReminder.NextReminderDate & vbCr & vbCr
    End If

Next MyReminder

CreateReportAsEmail "Snoozed Items", Report

End Sub


Function HasReminderFired(rmndr As Outlook.Reminder) As Boolean
    HasReminderFired = (rmndr.OriginalReminderDate <> rmndr.NextReminderDate)
End Function


' VBA SubRoutine which displays a report inside an email
' Programming by Greg Thatcher, http://www.GregThatcher.com

Public Sub CreateReportAsEmail(Title As String, Report As String)

    On Error GoTo On_Error

    Dim Session As Outlook.Namespace
    Dim mail As MailItem
    Dim MyAddress As AddressEntry
    Dim Inbox As Outlook.folder 

    Set Session = Application.Session
    Set Inbox = Session.GetDefaultFolder(olFolderInbox)
    Set mail = Inbox.items.Add("IPM.Mail")

    mail.Subject = Title
    mail.Body = Report

    mail.Save
    mail.Display

Exiting:
    Set Session = Nothing
    Set Inbox = Nothing
    Set mail = Nothing
    Exit Sub

On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
    Resume Exiting

End Sub

আপনি ভিবিএর সাথে অপরিচিত থাকলে স্লিপস্টিকের ব্যাখ্যা পৃষ্ঠাটি দেখুন । আপনি সম্পর্কে তথ্য পাবেন:

• ম্যাক্রো সুরক্ষা সেটিংস;
• কোডটি কোথায় রাখবেন (আপনি সন্নিবেশ | মডিউল সহ একটি নিয়মিত মডিউল ব্যবহার করতে পারেন); এবং
• কিভাবে একটি বোতাম তৈরি করতে।

Comments

এটি সেট আপ করা আরও কিছু কাজ, তবে ফলাফল দুর্দান্ত! আমি আমার আউটলুক সরঞ্জামদণ্ডে একটি বোতাম যুক্ত করেছি যা এটি ব্যবহারের জন্য বাতাস তৈরি করে।

— আরএসডাব্লু

Answer 2

এই দেখুন স্নুজযুক্ত আইটেম ফোরামের পোস্ট অনুসারে, স্নুজযুক্ত আইটেমগুলির একটি তালিকা দেখা সম্ভব নয়। পোস্টটি পরামর্শ দেয় যে আপনি একটি কাস্টম ভিউ তৈরি করে সীমিত পরিমাণে সহায়ক তথ্য দেখতে সক্ষম হতে পারেন যা কিছু অনুস্মারক ক্ষেত্র প্রদর্শন করে।

Answer 3

ক্যালেন্ডার ট্যাবে ক্লিক করার চেষ্টা করুন, দেখুন এবং দেখুন পরিবর্তনটি নির্বাচন করুন। তারপরে তালিকা নির্বাচন করুন। এটি সমস্ত অনুস্মারকগুলির একটি তালিকা দেখায়।

Comments

সুপার ইউজারে আপনাকে স্বাগতম। এই উত্তরটি প্রশ্নের পুরোপুরি সমাধান করে না। ওপি'র নির্দিষ্ট প্রশ্নের সমাধান করতে দয়া করে এটি সম্পাদনা করুন।

— আমি বলছি মনিকা পুনরায়