এমএস অফিসে এক সাথে কোনও ফাইলের নাম পরিবর্তন এবং পুরানো সংস্করণটি কীভাবে মুছবেন?

Question

মাইক্রোসফ্ট অফিসে, পূর্ববর্তী ফাইলের নামের একটি অনুলিপি না রেখে কোনও ফাইলকে অন্য কোনও ফাইল নামে সংরক্ষণ করতে চাইলে, এর জন্য দুটি পদক্ষেপ প্রয়োজন:

• প্রথমে ফাইল -> হিসাবে সংরক্ষণ করুন ... এবং নতুন নামটি নির্বাচন করুন। ফাইলটির একটি অনুলিপি তৈরি করা হয়েছে।
• তারপরে, উইন্ডোজ এক্সপ্লোরারে গিয়ে পুরানো নামটি সহ পুরানো ফাইলটি মুছুন।

আমি এক ধাপে অফিস থেকে নিজেই ফাইলটির "নাম পরিবর্তন" করে এই পদক্ষেপগুলি সহজ করতে চাই। আমি এই কিভাবে করতে পারে?

আরও বিনোদনমূলক এবং ক্রিপ্টিক সংস্করণের জন্য রিভিশন 1 দেখুন ।

Comments

@ রামহাউন্ড আমি অনুমান করি যে এটি কোনও সমাধানের ক্ষেত্রে কীভাবে সমস্যা নয় তা দেখতে আমি ব্যর্থ হয়েছি (ট্র্যাভিসের আরও ভাল সমাধান রয়েছে যে আমি যা করছি এবং রোভিউসার মনে হয় এটি সেরা উত্তরটি হয় কোনও ভিবিএ ম্যাক্রো - যা আমি করতে পারি, আমি কোনও কারণে এটি করার কথা

— ভাবেননি

একসাথে ? ঠিক আছে, যখন আপনি উত্তর পেয়ে

— যাবেন

আপনি পারবেন না কারণ ইইউ একীকরণকে সীমিত করেছে যা এমএসকে তার পণ্যগুলির মধ্যে করার অনুমতি দেয় allowed অফিসের কোনও ফাইলের নাম পরিবর্তন করার অনুমতি দেওয়ার ফলে সেগুলি নিয়মগুলি ভেঙে একচেটিয়া হয়ে যাবে

— চাদ

@ চাদ আপনি এখানে মজা করছেন? আমার অর্থ ওপেনঅফিস কেবল একটি পুনরায় নামকরণ ফাংশন যুক্ত করতে পারে।

— heinrich5991

Answer 1

এটির উত্তর দেওয়ার "সহজতম" উপায়টি এই উত্তরটির উপর উল্লেখযোগ্যভাবে বিল্ডিং করে বলে মনে হচ্ছে ।

1. সাধারণ.ডটম টেমপ্লেটে নিম্নলিখিত কোডটি সন্নিবেশ করুন ( C:\Documents and Settings\user name\Application Data\Microsoft\Templatesওয়ার্ডের জন্য উইন্ডোজ 7-তে পাওয়া গেছে )
2. Normal.dotm সংরক্ষণ করুন
3. এটি ওয়ার্ডের কুইললঞ্চ টুলবারে যুক্ত করুন।
4. Alচ্ছিক - এটিতে একটি কীবোর্ড শর্টকাট পুনরায় তৈরি করুন
5. Alচ্ছিক - ডিজিটালি আপনার টেম্পলেট স্বাক্ষর করুন (প্রস্তাবিত)

নোট করুন এটি পুরানো ফাইলটিকে পুরোপুরি ট্র্যাশ করার পরিবর্তে রিসাইকেল বিনে নিয়ে যায় এবং খুব সুবিধাজনক ফ্যাশনে নতুন ফাইলের নামও সেট করে।

---

Option Explicit

 'To send a file to the recycle bin, we'll need to use the Win32 API
 'We'll be using the SHFileOperation function which uses a 'struct'
 'as an argument. That struct is defined here:
Private Type SHFILEOPSTRUCT
    hwnd As Long
    wFunc As Long
    pFrom As String
    pTo As String
    fFlags As Integer
    fAnyOperationsAborted As Long
    hNameMappings As Long
    lpszProgressTitle As Long
End Type

 ' function declaration:
Private Declare Function SHFileOperation Lib "shell32.dll" Alias "SHFileOperationA" (lpFileOp As SHFILEOPSTRUCT) As Long

 'there are some constants to declare too
Private Const FO_DELETE = &H3
Private Const FOF_ALLOWUNDO = &H40
Private Const FOF_NOCONFIRMATION = &H10
Private Const FOF_SILENT = &H4

Function RecycleFile(FileName As String, Optional UserConfirm As Boolean = True, Optional HideErrors As Boolean = False) As Long
     'This function takes one mandatory argument (the file to be recycled) and two
     'optional arguments: UserConfirm is used to determine if the "Are you sure..." dialog
     'should be displayed before deleting the file and HideErrors is used to determine
     'if any errors should be shown to the user

    Dim ptFileOp As SHFILEOPSTRUCT
     'We have declared FileOp as a SHFILEOPSTRUCT above, now to fill it:
    With ptFileOp
        .wFunc = FO_DELETE
        .pFrom = FileName
        .fFlags = FOF_ALLOWUNDO
        If Not UserConfirm Then .fFlags = .fFlags + FOF_NOCONFIRMATION
        If HideErrors Then .fFlags = .fFlags + FOF_SILENT
    End With
     'Note that the entire struct wasn't populated, so it would be legitimate to change it's
     'declaration above and remove the unused elements. The reason we don't do that is that the
     'struct is used in many operations, some of which may utilise those elements

     'Now invoke the function and return the long from the call as the result of this function
    RecycleFile = SHFileOperation(ptFileOp)

End Function


Sub renameAndDelete()

    ' Store original name
    Dim sOriginalName As String
    sOriginalName = ActiveDocument.FullName

    ' Save As
    Dim sFilename As String, fDialog As FileDialog, ret As Long
    Set fDialog = Application.FileDialog(msoFileDialogSaveAs)

    'set initial name so you don't have to navigate to
    fDialog.InitialFileName = sOriginalName

    ret = fDialog.Show

    If ret <> 0 Then
        sFilename = fDialog.SelectedItems(1)
    Else
        Exit Sub
    End If

    Set fDialog = Nothing

    'only do this if the file names are different...
    If (sFilename <> sOriginalName) Then
        'I love vba's pretty code
         ActiveDocument.SaveAs2 FileName:=sFilename, FileFormat:= _
            wdFormatXMLDocument, LockComments:=False, Password:="", AddToRecentFiles _
            :=True, WritePassword:="", ReadOnlyRecommended:=False, EmbedTrueTypeFonts _
            :=False, SaveNativePictureFormat:=False, SaveFormsData:=False, _
            SaveAsAOCELetter:=False, CompatibilityMode:=14

        ' Delete original (don't care about errors, I guess)
        Dim hatersGonnaHate As Integer
        hatersGonnaHate = RecycleFile(sOriginalName, False, True)

    End If

End Sub

Comments

ভাল কাজ. এর মতো প্রশ্নোত্তরগুলি হ'ল সুপারউজারটি যা কিছু তা বোঝায়।

— এক্সডুমাইন

আমি এটি ব্যাপকভাবে ব্যবহার করা হয়। ধন্যবাদ সুপারইউসার!

— এন্ডারল্যান্ড

Answer 2

আপনি বিল্ট ইন কার্যকারিতা সহ এটি করতে পারবেন না। অফিস যেমন এটি ডকুমেন্টেশন বলে

একটি ফাইলের নাম পরিবর্তন করে একটি বিদ্যমান ফাইলের ফাইলের নাম পরিবর্তন করা হয়। যে কোনও প্রোগ্রামে কারও ফাইল খোলা থাকলে আপনি কোনও ফাইলের নাম পরিবর্তন করতে পারবেন না। ফাইলটি অবশ্যই বন্ধ করতে হবে এবং যদি এটি একটি ভাগ করা ফাইল হয় তবে অবশ্যই এটি অবশ্যই পরীক্ষা করে নেওয়া উচিত You

দেখে মনে হচ্ছে ভিএসটিও বা ভিবিএ (অলিভারের উত্তর হিসাবে) এর সাথে একটি কাস্টম "যেমন নাম পরিবর্তন করুন ..." ফাংশন তৈরি করে এমন কিছু তৈরি করা যেতে পারে । একটি নতুন অনুলিপি সংরক্ষণ করার জন্য আপনাকে কেবল এটিকে প্রোগ্রাম করতে হবে তবে পুরানোটি মুছুন।

Answer 3

এখানে আমি একটি ছোট ভিবিএ ম্যাক্রো ছুঁড়েছি যা আপনি যা চান ঠিক তেমন করে:

Sub Macro1()
    ' Store original name
    Dim sOriginalName As String
    sOriginalName = ActiveDocument.FullName

    ' Save As
    Dim sFilename As String, fDialog As FileDialog, ret As Long
    Set fDialog = Application.FileDialog(msoFileDialogSaveAs)
    ret = fDialog.Show
    If ret <> 0 Then
        sFilename = fDialog.SelectedItems(1)
    Else
        Exit Sub
    End If
    Set fDialog = Nothing

    ' Don't replace the original file
    If sFilename = sOriginalName Then Exit Sub

     ActiveDocument.SaveAs2 FileName:=sFilename, FileFormat:= _
        wdFormatXMLDocument, LockComments:=False, Password:="", AddToRecentFiles _
        :=True, WritePassword:="", ReadOnlyRecommended:=False, EmbedTrueTypeFonts _
        :=False, SaveNativePictureFormat:=False, SaveFormsData:=False, _
        SaveAsAOCELetter:=False, CompatibilityMode:=14

    ' Delete original
    Kill sOriginalName
End Sub

Comments

যেখানে Creditণ আছে সেখানে .ণ। আমি এটি চেষ্টা করতে রাজি ছিল না। ভিবিএ তাই কুরুচিপূর্ণ।

— এক্সডুমাইন

Answer 4

না, এটি কোনও বিল্ট ইন ফাংশন নয়।

চারপাশের একটি কাজ হ'ল নতুন নাম দিয়ে ফাইলটি সংরক্ষণ করা। তারপরে ফাইলটিতে ফিরে যান, হিসাবে সংরক্ষণ করুন এবং পুরানো ফাইলটি মুছুন যা এটি আপনার ডকুমেন্ট, এক্সপ্লোরার, নাম পরিবর্তনকরণ, পুনরায় খোলার চেয়ে আরও কার্যকর করে তোলে।

Comments

ড্রাইভিংয়ে যাওয়ার জন্য এই এক্সপ্লোরারটিতে যাওয়ার চেয়ে এটি আরও ভাল বিকল্প।

— এন্ডারল্যান্ড

Answer 5

এখানে @ ট্র্যাভিস উত্তরের উপর সামান্য প্রকরণ রয়েছে।

আবার এটি কোনও বিল্ট ইন ফাংশন নয়।

1. ওয়ার্ডে, ফাইলটি বন্ধ করুন, প্রয়োজনে পরিবর্তনগুলি সংরক্ষণ করার জন্য নিশ্চিত করে।
2. এখনও ওয়ার্ডে, একটি ফাইল খুলতে ক্লিক করুন।
3. প্রয়োজনে ফাইলটিতে নেভিগেট করুন, ফাইলটিতে ডান ক্লিক করুন এবং নামটি পরিবর্তন করুন।
4. ফাইল ওপেন ডায়ালগ থাকা অবস্থায়, নাম পরিবর্তন করা ফাইলটি খুলুন।
   

এই সমাধান:

1. পুরানো ফাইলটি মুছতে উইন্ডোজ এক্সপ্লোরারে দীর্ঘ একাকী ড্রাইভকে সরিয়ে দেয়।
2. ফাইল ওপেন / সেভ-অ্যাস কথোপকথনে কেবলমাত্র একটি ট্রিপ।
3. কেবল সংরক্ষণ-হিসাবে অপারেশন না করে আরও কয়েকটি মাউস-ক্লিক দিয়ে অপারেশন সম্পূর্ণ করে।
4. ভিবিএ বা অনুরূপ সমাধানের চেয়ে আরও কয়েকটি মাউস-ক্লিকগুলি সহ অপারেশন সম্পূর্ণ করে।