জিপি ব্যবহার করে স্থানীয় প্রশাসক পাসওয়ার্ড সেট করতে অক্ষম

Question

আমি আমাদের স্থানীয় অ্যাডমিন স্ক্রিপ্ট আপডেট করছি যা সার্ভারে 2008 আর 2 অন্তর্ভুক্ত নয়।

2008 এবং উইন্ডোজ 7 এর একই সংস্করণ মাইক্রোসফ্ট উইন্ডোজ [সংস্করণ 6.1.7601] রয়েছে তাই আমি কোনও সংস্করণ অনুসন্ধান করতে পারি না।

আমি এই বিকল্প চেষ্টা করেছি

systeminfo |findstr /B /C:"OS Name"|find "2008"
if not ERRORLEVEL 1 goto W2008

অথবা

wmic OS get Caption|find "2008"
if not ERRORLEVEL 1 goto W2008

তবে দুটি বিকল্পই ব্যর্থ। স্ক্রিপ্টটি জিপি থেকে চালিত হয় এবং এটি কম্পিউটারে প্রয়োগ হয়

@echo off
setlocal
:: Set full path to logfile:
set logfile=C:\temp\pwd.log
:: Initialise logfile:
date /T >%logfile%
echo Starting pwd.log on %computername% >>%logfile%
:: ##############################################################
:: Set the required passwords here:
set ntw2kadmin=ntwpass
set xpvistaadmin=xppass
set w2k3admin=2003pass
set w2k8admin=P2008pass
:: ##############################################################
:: Exceptions:
if /I "%COMPUTERNAME%"=="PC1" goto SKIP
if /I "%COMPUTERNAME%"=="PC2" goto SKIP
if /I "%COMPUTERNAME%"=="PC3" goto SKIP
:: Set password based on OS version: 
ver|find "4.0" >nul
if not ERRORLEVEL 1 goto NTW2K
ver|find "5.0" >nul
if not ERRORLEVEL 1 goto NTW2K
ver|find "5.1" >nul
if not ERRORLEVEL 1 goto XPVISTA
ver|find "5.2" >nul
if not ERRORLEVEL 1 goto 2K3
ver|find "6.0" >nul|
if not ERRORLEVEL 1 goto XPVISTA
wmic OS get Caption|find "2008"
if not ERRORLEVEL 1 goto W2008

:: Catch any unusual circumstances:
goto XPVISTA
:NTW2K
echo Setting local administrator password for this NT4 or Windows 2000 machine >>%logfile%
net user Administrator %ntw2kadmin% 2>&1 >>%logfile%
goto EOF
:XPVISTA
echo Setting local administrator password for this XP or Vista or Win 7 machine >>%logfile%
net user Administrator %xpvistaadmin% 2>&1 >>%logfile%
goto EOF
:2K3
echo Setting local administrator password for this Windows 2003 Server >>%logfile%
net user Administrator %w2k3admin% 2>&1 >>%logfile%
goto EOF
:W2008
echo Setting local administrator password for this Windows 2008 r2 Server >>%logfile%
net user Administrator %w2k8admin% 2>&1 >>%logfile%
goto EOF
:SKIP
echo Not setting local administrator password for %COMPUTERNAME% >>%logfile%
goto EOF
:EOF
echo setlapwd.bat: exiting >>%logfile%
:: Remove user permissions from the logfile's ACL:
cacls %logfile% /E /R BUILTIN\Users
:: End our local scope:
endlocal

আপডেট: স্ক্রিপ্টটি উইন্ডোজ 2000, উইন্ডোজ এক্সপি, উইন্ডোজ 7, ​​উইন্ডোজ সার্ভার 2003 এ প্রয়োগ হয়েছে তবে উইন্ডোজ 2008 আর 2 তে নয়

Comments

আপনি স্ক্রিপ্টের পরিবর্তে গ্রুপ নীতিতে ডাব্লুএমআই ফিল্টার ব্যবহার করছেন না কেন?

— ট্যানার ফকনার

এইভাবেই সংস্থাটি এটি করে আমি বললাম আমরা এটি করতে জিপি ব্যবহার করতে পারি তবে আমাকে এটি ঠিক করতে বলা হয়েছিল। আমি স্ক্রিপ্টটি আপডেট করার চেষ্টা করি কিন্তু 7 এবং 2008 একই সংস্করণটি ব্যবহার করি

— জেমস

Answer 1

এটি আমার জন্য পুরোপুরি কাজ করেন:

wmic OS get Caption|find "2008"
if not ERRORLEVEL 1 goto W2008

আমার ধারণা ত্রুটিটি এই স্ক্রিপ্টের অন্য কোথাও রয়েছে। আর একটু সমস্যা সমাধানের ব্যবস্থা হতে পারে।

পুরো স্ক্রিপ্টটি যদিও জগাখিচুড়ি মনে হচ্ছে। আমি একটি প্রতিস্থাপন হিসাবে পাওয়ারশেল স্ক্রিপ্টের জন্য চাপ দিয়েছি এবং সম্ভবত সঠিক ডাব্লুএমআই ফিল্টার ব্যবহার করতে পারি। বা আরও ভাল, নিম্নলিখিত GPO সক্ষম করুন:

Computer Configuration, Windows Settings, Security Options, Account: Administrator account status, Disabled

স্থানীয় অ্যাডমিন প্রোফাইলগুলি প্রথমে কোনও ভাল ধারণা নয়।

Comments

ডাব্লুএমইসি ওএস ক্যাপশন পান | "২০০৮" সন্ধান করুন না যদি এরোলারভেল 1 না হয় W2008 যখন আমি আমার পিসিতে এটি চালনা করি তবে এটি ঠিক কাজ করে তবে পিসিতে বেকুয়াস জিপি প্রয়োগ করা হয়, যখন পিসি শুরু হয় এটি কেবল ডাব্লিমিকে উপেক্ষা করে। যদি আমি এটি মুছে ফেলি তবে এটি উইন্ডোজ 7 এবং 2008 এর জন্য দুর্দান্ত কাজ করে তবে সমস্যাটি হ'ল উইন 7 এবং উইন ২০০৮ এর একই সংস্করণ নম্বর রয়েছে

— জেমস

আমাদের পাওয়ারশেল লিপিটি থাকতে পারে না। আমাদের এমন সিস্টেম রয়েছে যা 2000 এবং এমনকি 95 জয়ের চলমান রয়েছে

— জেমস

@ জামেস হলি% * @! উইন্ডোজ 95? সেক্ষেত্রে আমি আপনাকে নতুন কর্মসংস্থান সন্ধান করার পরামর্শ দিচ্ছি। সিরিয়াসলি। পুরানো ব্যবস্থা এবং পদ্ধতিগুলির অভিজ্ঞতা কী ভাল?

— ট্যানার ফকনার

Answer 2

উত্তর এখানে। আমি আমাদের বিজ্ঞাপনটি অনুসন্ধানের জন্য ডিএসকিয়ারি ব্যবহার করেছি, যদি এটি সার্ভার থেকে থাকে তবে ডেস্কটপ হিসাবে অন্য সার্ভার হিসাবে প্রক্রিয়া করে।

@echo off
:: Limit scope:
setlocal
:: Set full path to logfile:
set logfile=C:\tmp\passlog.log
:: Initialise logfile:
date /T >%logfile%
echo Starting passlog.bat on %computername% >>%logfile%
:: ##############################################################
:: Set the required passwords here:
::windows 2003 password
set w2k3admin=pass1
::windows 2008 password
set w2k8admin=Pass1
::windows xp, vista, 7 and 8 password
set desktopadmin=pcpass
:: ##############################################################
:: We need a copy of dsquery.exe on the local machine:
echo check dsquery file... >>%logfile%
if not exist %windir%\system32\dsquery.exe copy "\\shared\location\scripts\dsquery.exe" %windir%\system32\dsquery.exe
echo dsquery filed checked... >>%logfile%
:: Are we ignoreOU?
call dsquery computer -name %computername% | findstr /i "OU=ignoreOU"
if not ERRORLEVEL 1 goto ignoreOU
:: Are we a server?
call dsquery computer -name %computername% | findstr /i "OU=Servers"
if not ERRORLEVEL 1 goto server
:: Are we a DC?
call dsquery computer -name %computername% | findstr /i /C:"OU=Domain Controllers"
if not ERRORLEVEL 1 set goto server
::
goto desktop
:server
    ver|find "6.1" >nul
        if not ERRORLEVEL 1 goto 2k8
    ver|find "5.2" >nul
        if not ERRORLEVEL 1 goto 2k3
:2k8
    echo Setting local administrator password for windows server 2008... >>%logfile%
    net user Administrator %w2k8admin% 2>&1 >>%logfile%
    goto EOF
:2k3
    echo Setting local administrator password for windows server 2003... >>%logfile%
    net user Administrator %w2k3admin% 2>&1 >>%logfile%
    goto eof
:desktop
    echo Setting local administrator password for desktop/laptop... >>%logfile%
    net user Administrator %desktopadmin% 2>&1 >>%logfile%
    goto eof
:ignoreOU
    echo Not setting local administrator password for this ignoreOU server... >>%logfile%
    goto eof
:eof
echo passlog.bat: exiting >>%logfile%
:: Remove user permissions from the logfile's ACL:
cacls %logfile% /E /R BUILTIN\Users
:: End our local scope:
endlocal