বিভিন্ন পরিবেশের মধ্য দিয়ে স্ট্রিংগুলি পাস করার সময় একজনকে অবশ্যই খুব সতর্কতা অবলম্বন করতে হবে।
আমি 10.4 রান করি, সুতরাং আমার 'tfork' স্ক্রিপ্ট সর্বদা পরিবর্তে একটি নতুন উইন্ডো খোলে। এটি কোনও ট্যাব ব্যবহার করতে খাপ খাইয়ে নেওয়া সহজ হওয়া উচিত:
#!/bin/sh
# source: http://www.pycs.net/bob/weblog/2004/02/23.html#P49
# Rewritten to use osascript args -> run handler args.
# Added ability to pass additional initial command and args to new shell.
# Bug: Non ASCII characters are unreliable on Tiger.
# Tiger's osascript seems to expect args to be encoded in
# the system's primary encoding (e.g. MacRoman).
# Once in AppleScript, they are handled OK. Terminal sends them
# back to the shell as UTF-8.
test $# -eq 0 && set -- : # default command if none given
osascript - "$(pwd)" "$@" <<\EOF
on run args
set dir to quoted form of (first item of args)
set cmd_strs to {}
repeat with cmd_str in rest of args
set end of cmd_strs to quoted form of cmd_str
end
set text item delimiters to " "
set cmd to cmd_strs as Unicode text
tell app "Terminal" to do script "cd " & dir & " && " & cmd
end
EOF
উদাহরণ: tfork git log -p ..FETCH_HEAD
সংশোধন: একটি টার্মিনাল ট্যাব ইতিমধ্যে চলমান প্রক্রিয়াটির সিডব্লিউডি occup
"বর্তমান ট্যাবটি দখল করে থাকা প্রোগ্রামটির বর্তমান ডিরেক্টরি" ধারণাটি যেমন প্রত্যাশা করতে পারে তেমন সুস্পষ্ট নয়।
প্রতিটি টার্মিনাল ট্যাবটিতে একটি একক tty ডিভাইস থাকে যা এটি চালিত প্রক্রিয়াগুলি দ্বারা ব্যবহৃত হয় (প্রাথমিকভাবে, একটি শেল; তারপরে, শেলটি যা শুরু হয়)।
প্রতিটি (স্বাভাবিক) টার্মিনাল টিটির একটি একক অগ্রভাগ প্রক্রিয়া গ্রুপ থাকে যা টিটিটি "দখল" হিসাবে বিবেচনা করতে পারে।
প্রতিটি প্রক্রিয়া গ্রুপের এটিতে একাধিক প্রক্রিয়া থাকতে পারে।
প্রতিটি প্রক্রিয়াটির নিজস্ব চলমান ডিরেক্টরি ডিরেক্টরি (সিডব্লিউডি) থাকতে পারে (কিছু পরিবেশ প্রতিটি থ্রেডকে তাদের নিজস্ব সিডব্লিউড বা সিডব্লিউড-সমতুল্য দেয়, তবে আমরা এটিকে উপেক্ষা করব)।
পূর্ববর্তী তথ্যগুলি এক ধরণের ট্রেইল স্থাপন করে যা tty থেকে cwd: tty -> অগ্রভাগ প্রক্রিয়া গোষ্ঠী -> অগ্রভূমি প্রক্রিয়া গোষ্ঠীর প্রক্রিয়া -> সিডব্লিউডি।
সমস্যার প্রথম অংশ (টিটিআই থেকে অগ্রভূমি প্রক্রিয়াগুলি) পিএস থেকে আউটপুট দিয়ে সমাধান করা যেতে পারে :
ps -o tty,pid,tpgid,pgid,state,command | awk 'BEGIN{t=ARGV[1];ARGC=1} $1==t && $3==$4 {print $2}' ttyp6
(যেখানে "ttyp6" হ'ল আগ্রহের নাম)
প্রক্রিয়া (পিআইডি) থেকে সিডব্লিউডিতে ম্যাপিংটি lsof দিয়ে তৈরি করা যায় :
lsof -F 0n -a -p 2515,2516 -d cwd
(যেখানে "2515,2516" হ'ল আগ্রহের প্রক্রিয়াগুলির একটি কমা-বিচ্ছিন্ন তালিকা)
তবে বাঘের নীচে, আমি কোনও নির্দিষ্ট টার্মিনাল উইন্ডোর টিটিআই ডিভাইসের নাম পাওয়ার সরাসরি কোনও উপায় দেখতে পাচ্ছি না । বাঘে টিটিটির নাম পাওয়ার একটি মারাত্মক কুৎসিত উপায় রয়েছে। চিতাবাঘ বা স্নো চিতা আরও ভাল করতে পারে।
আমি এগুলি একটি অ্যাপলস্ক্রিপ্টে সব মিলিয়ে রেখেছি:
on run
(* Find the tty. *)
-- This is ugly. But is seems to work on Tiger. Maybe newer releases can do better.
tell application "Terminal"
set w to window 1
tell w
set origName to name
set title displays device name to not title displays device name
set newName to name
set title displays device name to not title displays device name
end tell
end tell
set tty to extractTTY(origName, newName)
if tty is "" then
display dialog "Could not find the tty for of the current Terminal window." buttons "Cancel" cancel button "Cancel" default button "Cancel"
end if
(* Find the PIDs of the processes in the foreground process group on that tty. *)
set pids to paragraphs of (do shell script "
ps -o pid,tty,tpgid,pgid,state,command |
awk '
BEGIN {t=ARGV[1];ARGC=1}
$2==t && $3==$4 {print $1}
' " & quoted form of tty)
if pids is {} or pids is {""} then
display dialog "Could not find the processes for " & tty & "." buttons "Cancel" cancel button "Cancel" default button "Cancel"
end if
(* Find the unique cwds of those processes. *)
set text item delimiters to {","}
set lsof to do shell script "lsof -F 0n -a -d cwd -p " & quoted form of (pids as Unicode text) without altering line endings
set text item delimiters to {(ASCII character 0) & (ASCII character 10)}
set cwds to {}
repeat with lsofItem in text items of lsof
if lsofItem starts with "n" then
set cwd to text 2 through end of lsofItem
if cwds does not contain cwd then ¬
set end of cwds to cwd
end if
end repeat
if cwds is {} then
display dialog "No cwds found!?" buttons "Cancel" cancel button "Cancel" default button "Cancel"
end if
if length of cwds is greater than 1 then
set cwds to choose from list cwds with title "Multiple Distinct CWDs" with prompt "Choose the directory to use:" without multiple selections allowed and empty selection allowed
if cwds is false then error number -128 -- cancel
end if
(* Open a new Terminal. *)
tell application "Terminal" to do script "cd " & quoted form of item 1 of cwds
end run
to extractTTY(a, b)
set str to textLeftAfterRemovingMatchingHeadAndTail(a, b)
set offs to offset of "tty" in str
if offs > 0 then
return text offs through (offs + 4) of str
end if
return ""
end extractTTY
to textLeftAfterRemovingMatchingHeadAndTail(big, little)
set text item delimiters to space
if class of big is not list then set big to text items of big
if class of little is not list then set little to text items of little
set {maxLen, minLen} to {length of big, length of little}
if maxLen < minLen then ¬
set {big, little, maxLen, minLen} to {little, big, minLen, maxLen}
set start to missing value
repeat with i from 1 to minLen
if item i of big is not equal to item i of little then
set start to i
exit repeat
end if
end repeat
if start is missing value then
if maxLen is equal to minLen then
return ""
else
return items (minLen + 1) through end of big as Unicode text
end if
end if
set finish to missing value
repeat with i from -1 to -minLen by -1
if item i of big is not equal to item i of little then
set finish to i
exit repeat
end if
end repeat
if finish is missing value then set finish to -(minLen + 1)
return items start through finish of big as Unicode text
end textLeftAfterRemovingMatchingHeadAndTail
এটিকে স্ক্রিপ্ট এডিটর ( স্নো চিতাবাঘে অ্যাপলস্ক্রিপ্ট সম্পাদক ) দিয়ে সংরক্ষণ করুন এবং কোনও কীতে নির্ধারিত করতে একটি লঞ্চার (উদাহরণস্বরূপ ফাস্টস্ক্রিপ্ট ) ব্যবহার করুন (বা কেবল এটি অ্যাপলস্ক্রিপ্ট মেনু থেকে চালান ( অ্যাপ্লিকেশনস / অ্যাপলস্ক্রিপ্ট / অ্যাপলস্ক্রিপ্ট ইউটিলিটি.অ্যাপের মাধ্যমে সক্ষম ))।