প্রদত্ত উইন্ডো আকার সহ আমি কীভাবে কনসোল অ্যাপ্লিকেশনটি খুলতে পারি?

16

আমি যে অ্যাপ্লিকেশনটি শুরু করতে চাই তা হ'ল মঙ্গোডিবি। যদি আমি এটি স্বাভাবিকভাবে শুরু করি তবে এটি দেখতে এমন দেখাচ্ছে:

এখানে চিত্র বর্ণনা লিখুন

আমি লাইন ব্রেকগুলির পরিমাণ পছন্দ করি না এবং আমার স্ক্রিনের প্রচুর স্থান রয়েছে, তাই আমি লাইন ব্রেকগুলি থেকে মুক্তি পাওয়ার জন্য স্পেসটি ব্যবহার করতে চাই।

আমি এটি দিয়ে কনসোল উইন্ডোর আকার পরিবর্তন করতে পারি MODE, তাই আমি এই জাতীয় ব্যাচ ফাইলটি লিখেছিলাম:

@ECHO OFF
MODE con:cols=140 lines=70
%~dp0mongodb\bin\mongod --dbpath %~dp0data --rest

এ পর্যন্ত সব ঠিকই. আমি যখন এই ব্যাচ ফাইলটি শুরু করি, তখন আমি পছন্দসই আকারে আরও বড় উইন্ডোটি পাই।

তবে আমি যখন এখন মোংগোডিবি থেকে বেরিয়ে আসার জন্য Ctrl+ Cটিপছি তখন আমি বিরক্তিকর প্রম্পটটি পেয়েছি:

Terminate batch job (Y/N)?

কোনটি অকেজো, কারণ আমি যে কমান্ডটি সবেমাত্র বের করে দিয়েছিলাম তা ব্যাচ কাজের সর্বশেষ কমান্ড ছিল যাই হোক না কেন এবং আমি যা উত্তর দিই না কেন, ফলাফলটি একই।

সুতরাং, আমি Ctrl+ টি আঘাত করার সময় প্রম্পটটি না রেখে আমি কীভাবে আরও বড় কনসোল উইন্ডো পেতে পারি C?

windows command-line batch-file

— ডের হচস্টাপলার
সূত্র

12

আমি একটি ছোট সি # অ্যাপ্লিকেশন বাস্তবায়ন করতে আজ কয়েক ঘন্টা ব্যয় করেছি যা অন্য কনসোল অ্যাপ্লিকেশনটি মোড়ানো করতে পারে এবং কনসোল হোস্টের উইন্ডোর আকার সামঞ্জস্য করতে পারে।

console-wrapperব্যবহার করা সহজ। এটি কেবলমাত্র কয়েকটি কমান্ড লাইন প্যারামিটারের প্রত্যাশা করে:

Usage: console-wrapper.exe [OPTIONS]

Options:

      --subject=VALUE        The application that should be started by the
                               console wrapper.
      --width=VALUE          The desired width of the console window.
      --height=VALUE         The desired height of the console window.
  -h, -?, --help             Shows this help message

--widthএবং --heightফলাফল কনসোল উইন্ডোর আকার সেট করতে ব্যবহৃত হয়। --subjectallyচ্ছিকভাবে ব্যবহার করা যেতে পারে, যদি এটি বাদ দেওয়া হয় তবে অবশিষ্ট পরামিতিগুলি কমান্ড হিসাবে বিবেচনা করা হবে (পরামিতি সহ) শুরু করার জন্য।

সুতরাং এখন আমি আমাদের স্টার্টআপ স্ক্রিপ্টে চূড়ান্ত কলটি হচ্ছি:

START "MongoDB" database\console-wrapper.exe --width=140 --height=70 %~dp0database\mongodb\bin\mongod.exe --dbpath %~dp0database\data --rest

ফলস্বরূপ উইন্ডোটিতে অনুরোধ করা আকার এবং Ctrl+ টিপানোর Cপরে উইন্ডোটি বন্ধ হয়ে যাবে (সঠিকভাবে অন্তর্ভুক্ত প্রক্রিয়াটি বন্ধ করার পরে)।

— ডের হচস্টাপলার
সূত্র

6

আপনি কি এটি পাওয়ারশেল স্ক্রিপ্ট থেকে চালানো বিবেচনা করেছেন? পাওয়ারশেল এটি নিজস্ব উইন্ডোর আকার পরিবর্তন করতে সক্ষম

$h = Get-Host
$buf = $h.UI.RawUI.BufferSize
$buf.Width = 300
$h.ui.rawui.BufferSize = $buf
$win = $h.UI.RawUI.WindowSize
$win.Width = 150
$h.ui.rawui.WindowSize = $win
#Command to start mongodb here.

এটি 150 মাপের একটি উইন্ডো তৈরি করে তবে 300 এর পাশের দিকে স্ক্রোলযোগ্য বাফার রয়েছে।

— স্কট চেম্বারলাইন
সূত্র

হ্যাঁ, আমি এটি বিবেচনা করেছি, তবে কীভাবে সেই সময়ে এটি প্রয়োগ করতে হবে তা জানতাম না। এটি পুরোপুরি কাজ করে, সামান্য বিরক্তি ব্যতীত যে স্ক্রিপ্টগুলি কার্যকর করা সম্ভব হয়।

— ডের হচস্টাপলার

5

আমি যতদূর প্রশ্নটি বুঝতে পারি, আপনি চান মোঙ্গোডিবিতে কনসোল উইন্ডোটির নির্দিষ্ট আকার থাকতে হবে এবং আপনি Ctrl+ টিপলে প্রস্থান করতে হবে C। তাহলে উত্তরটি বেশ সহজ: শর্টকাটটি এটি শুরু করতে ব্যবহার করুন ।

আমার mongodএক্সিকিউটেবল নেই, তাই আমি perl.exeউদাহরণ হিসাবে ব্যবহার করব । আপনি এটি রান ডায়ালগ ( Windows+ R) থেকে শুরু করার পরে , কনসোল উইন্ডোর আকারটি 300 লাইনের জন্য বাফার আকারের সাথে মান 80 × 25 হবে ×

mongod(অথবা perlআমার ক্ষেত্রে) একটি শর্টকাট তৈরি করুন ।
শর্টকাটটিতে ডান ক্লিক করুন এবং বৈশিষ্ট্যগুলি ক্লিক করুন ।
1. উপর শর্টকাট ট্যাবটি উদ্দিষ্ট ক্ষেত্র, এর প্যারামিটার যোগ mongod।
2. ফিল্ড ইন স্টার্ট শুরু হওয়া প্রোগ্রামের প্রাথমিক বর্তমান ডিরেক্টরি নিয়ন্ত্রণ করে। ডিফল্টরূপে এটি ডিরেক্টরি হয় যেখানে .exe অবস্থিত।
লেআউট ট্যাবে ক্লিক করুন ।
1. উইন্ডোর আকার 140 × 70 এ পরিবর্তন করুন ।
2. আপনি পুরানো বার্তাগুলি পর্যন্ত স্ক্রোল করতে সক্ষম হওয়ার জন্য স্ক্রিন বাফারের উচ্চতা 1000 বা আরও বেশি করতে পারেন।
3. আপনি যদি লেট সিস্টেমের পজিশন উইন্ডোটি সাফ করেন , আপনি স্ক্রিনে কনসোল উইন্ডোর অবস্থান নির্দিষ্ট করতে পারেন।
শর্টকাট বৈশিষ্ট্যগুলি বন্ধ করতে ওকে ক্লিক করুন ।

এখন আপনি যখন এই শর্টকাটটি ক্লিক করবেন, কনসোল উইন্ডোটি নির্দিষ্ট আকারের হবে। আপনি যখন Ctrl+ Cটিপেন, অ্যাপ্লিকেশনটি প্রস্থান হয় এবং উইন্ডো কোনও অতিরিক্ত প্রম্পট ছাড়াই বন্ধ হয়।

রান ডায়ালগটি চালু করার পরে আপনি উইন্ডোটির বিন্যাসটিও পরিবর্তন করতে পারবেন । কনসোল উইন্ডোর শিরোনামটিতে ডান ক্লিক করুন এবং বৈশিষ্ট্যগুলি ক্লিক করুন । লেআউট ট্যাবে ক্লিক করুন , উইন্ডোর আকার সামঞ্জস্য করুন এবং বৈশিষ্ট্যগুলি বন্ধ করতে এবং তত্ক্ষণাত পরিবর্তনগুলি প্রয়োগ করতে ওকে ক্লিক করুন । (উইন্ডোটি শর্টকাট থেকে শুরু করা হলে শর্টকাটের বৈশিষ্ট্য আপডেট করা হয়))

পরের বার আপনি একই অ্যাপ্লিকেশনটি শুরু করবেন, কনসোল উইন্ডোটির আকারটি জাদুগতভাবে একই আকারের হবে। (আমি এবার এটি পরীক্ষা করে দেখিনি তবে এটি কাজ করত))

— আলেক্সি ইভানভ
সূত্র

এর অবস্থান mongod.exeনির্দিষ্ট করা হয়নি। এটি প্রয়োগের উপর নির্ভর করে পরিবর্তন হবে। যে কারণে আমি সরাসরি কনসোলের মাধ্যমে সমাধানের লক্ষ্য নিয়েছিলাম। আমি যখন শর্টকাটের জন্য লক্ষ্য বা কার্যকারী ডিরেক্টরি ক্ষেত্রগুলিতে কোনও আপেক্ষিক পথ রাখি তখন তা সেগুলি গ্রহণ করবে না :(

— ডের হচস্টাপলার

@ অলিভারসালজবার্গ আপনি কি ব্যাচটি পুনরায় শুরু করার পদ্ধতির চেষ্টা করেছিলেন ? আমি বলতে চাইছি আপনার ব্যাচটি নিজে থেকেই শুরু হয় start cmd /kএবং অতিরিক্ত প্যারামিটারটি পাস করে বা একটি পরিবেশের ভেরিয়েবল সেট করে। দ্বিতীয় উদাহরণটি তখন কনসোল উইন্ডোর আকার পরিবর্তন করে শুরু হয় mongod.exe।

— আলেক্সি ইভানভ 18

হ্যাঁ, আমি অনেক কিছু চেষ্টা করেছিলাম। তবে যতক্ষণ না ব্যাচের ফাইল জড়িত রয়েছে ততক্ষণ সমাধানটি Terminate batch job (Y/N)?প্রম্পটে ভুগবে : actually যদিও আমার পক্ষে এটি সমাধান করার জন্য আমি আসলে একটি রেপার অ্যাপ্লিকেশন বাস্তবায়ন শেষ করেছি।

— ডের হচস্টাপলার

অলিভারসালজবার্গ এটি একটি খুব দরকারী ইউটিলিটি হবে। আমি আরও ভেবেছিলাম যে একটি মোড়কের একমাত্র উপায় হবে ...

— আলেক্সি ইভানভ

3

ডিফল্ট কনসোল লেআউট সেটিংস এখানে রেজিস্ট্রিতে লাইভ:

[HKEY_CURRENT_USER\Console]

আপনি এই সেটিংসটি সংশোধন করতে পারেন এবং সেগুলি পথ নির্বিশেষে চালু হওয়া সমস্ত কমান্ড উইন্ডোতে প্রযোজ্য হবে। দুর্ভাগ্যক্রমে, কাঁচা মানগুলি মানববান্ধব নয়।

তাদের যেভাবে আপনি চান সেভাবে সেট করতে একটি নিয়মিত সেন্টিমিডি উইন্ডো খুলুন, তারপরে আপনার পছন্দ অনুযায়ী সেটিংস সম্পাদনা করুন। উপরের পাথরে রেজিস্ট্রিটি দেখুন এবং আপনাকে "কনসোল" এর অধীনে একটি সাব কী কী সেন্টিমিডে দেখতে পাবেন e সেই চাবিটি কোনও ফাইলে রফতানি করুন, উপরের দিকটি পরিবর্তন করুন এবং আমদানি করুন, বা ম্যানুয়ালি মানগুলি এক থেকে অন্যটিতে অনুলিপি করুন। এরপরে আপনি cmd.exe নির্দিষ্ট এন্ট্রি মুছতে পারেন। এখন, খোলার সমস্ত কমান্ড উইন্ডোগুলি পরিবর্তিত ডিফল্ট ব্যবহার করবে।

আমি আমার স্ট্যান্ডার্ড ডিফল্টগুলি দিয়ে বেশ কয়েকটি রেজিস্ট্রি এন্ট্রি ফাইল তৈরি করা সহজ বলে মনে করেছি যাতে আমি যখন প্রথমবারের মতো আরডিপি করি তখন আমি সহজেই এগুলিকে একটি নতুন সার্ভারে পপ করতে পারি। আমি সাধারণত যে দুটি আকারের ব্যবহার করি তার জন্য আমি প্রসেট তৈরি করেছি।

1024 x 768 এর জন্য (আমি সাধারণত মাল্টি সেশন আরডিপি সরঞ্জামের মাধ্যমে অ্যাক্সেস করা সার্ভারগুলির জন্য এটি ব্যবহার করি):

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Console]
"ScreenBufferSize"=dword:012c0050
"WindowSize"=dword:00190050
"WindowPosition"=dword:000a000a
"FontSize"=dword:000c0007
"FontFamily"=dword:00000030
"FontWeight"=dword:00000190
"FaceName"="Terminal"
"QuickEdit"=dword:00000001

1280 x 1024 এর জন্য:

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Console]
"ScreenBufferSize"=dword:0bb800af
"WindowSize"=dword:004b00af
"WindowPosition"=dword:000a000a
"FontSize"=dword:000c0007
"FontFamily"=dword:00000030
"FontWeight"=dword:00000190
"FaceName"="Terminal"
"QuickEdit"=dword:00000001

— পিটার
সূত্র

0

রাখুন StartMongoDB কলিং সামনে কমান্ড। আমি বিশ্বাস করি যে এটি ঠিক করা উচিত।

— Keltari
সূত্র

না, এটি একটি নতুন কনসোল উইন্ডোতে মঙ্গোডিবি খুলবে। আমি যখন start /bএটি ব্যবহার করব তখন আমি Ctrl + C চাপার পরে কনসোল উইন্ডোটি উন্মুক্ত ছেড়ে দেবে।

— ডের হচস্টাপলার

0

আপনি যদি বেশ কয়েকটি ক্ষুদ্র সহায়ক প্রোগ্রামের সাথে একটি ব্যাচ ফাইল চালাতে খুশি হন তবে আমার দ্বারা এখানে একটি সম্পূর্ণ সমাধান পোস্ট করা হয়েছে:
কীভাবে একটি ব্যাচ ফাইল কোনও প্রোগ্রাম চালাতে পারে এবং উইন্ডোর অবস্থান এবং আকার নির্ধারণ করতে পারে?

নীচের বিষয়বস্তু। । । ।

এই ডেমো ব্যাচ ফাইলটি একটি কমান্ড-লাইন প্রোগ্রাম চালাবে এবং এর কমান্ড প্রম্পট কনসোল উইন্ডোর অবস্থান এবং আকার নির্ধারণ করবে। এই ব্যাচের সাধারণ থিমটি আগের দুটি সমাধানের মতো (উপরের লিঙ্কের স্ট্যাক ওভারফ্লো পৃষ্ঠায়), তবে এই কাজটি করার জন্য কিছু অনন্য সমস্যা এবং কাজের ক্ষেত্র ছিল - এটি একটি সিএমডি হোস্ট করা একটি কমান্ড প্রম্পট উইন্ডো is .EXE 'এবং' EXPLORER.EXE 'এর মতো কোনও জিইউআই উইন্ডো নয়।

আরও তথ্যের জন্য ব্যাচ ফাইলে সমস্ত মন্তব্য এবং বিবরণ পড়ুন।

ব্যবহৃত সরঞ্জামগুলি:
1. মনিটরআইনফো দেখুন Nir সোফের দ্বারা (41 কিলোবাইট)
2. NirCmd Nir সোফের দ্বারা (43 কিলোবাইট)
3. GetPIDs ড্যানিয়েল Scheibli দ্বারা (280 কিলোবাইট)
4. upx.exe --- কম্যান্ড-লাইন প্রোগ্রাম আমরা এই ডেমো জন্য ব্যবহার করবে হয়; এটি ব্যাচ ফাইলের মতো একই ডিরেক্টরিতে রাখুন।
৫. একটি ব্যাচ ফাইল --- নীচে দেখুন

পাঁচটি ফাইল ডিরেক্টরিতে জড়ো করুন। এটি ব্যাচ ফাইল যা কোনও উইন্ডোজ সিস্টেমে চালানোর জন্য প্রস্তুত।

এই ডেমো ব্যাচটি যা করতে চলেছে, আপনাকে একটি কাস্টম কনসোল উইন্ডো উপস্থাপন করা বাদ দিয়ে, এটি কি upx.exeকমান্ড-লাইন সুইচগুলির সাথে চলবে?--best -v -o getpids-compressed.exe getpids.exe। আমরা আমাদের সরঞ্জাম 'গেটপিআইডি' কে 88 কেবি পর্যন্ত সংকোচিত করতে যাচ্ছি ........ চালু করার পরে, একটি আকর্ষণীয় ঘটনা দেখতে এই কনসোল উইন্ডোর শিরোনাম বারে ডাবল ক্লিক করুন; এই কনসোল উইন্ডোটি জিইউআইয়ের মতো আচরণ করে!

@echo off
setlocal enabledelayedexpansion enableextensions
pushd %~dp0%

REM ----- ADD SOME USEFUL INFORMATION TO THIS CONSOLE WINDOW TITLE.
for /f "tokens=3" %%A in ('getpids.exe') do set _PROCESS_ID_=%%A
title This batch file runs a command-line program and sets the position and size of its console window        (PROCESS ID = %_PROCESS_ID_%)

REM ********************** DESCRIPTION ************************************
REM ** This script opens a command-line program console window with specified
REM ** screen properties at the primary monitor (containing the taskbar).
REM ** The "X/Y position" and "W/H size" of the console window is auto-set by
REM ** this script and the monitor resolution is auto-calculated to suit.
REM ** 'MonitorInfoView.exe' is the helper tool used to capture the resolution
REM ** info of the monitor.
REM ** 'nircmd.exe' is the tool performing all the display trickery.
REM ** 'getpids.exe' is the helper tool used to capture the Process ID of the
REM ** working batch file, thus allowing us to identify which CMD.EXE host this
REM ** console window belongs to when looking at Task Manager.
REM **
REM ** To tweak this script, go to the code section named:
REM ** >>>>> USER INPUT/PREFERENCES ARE ALL SET HERE <<<<<
REM ***********************************************************************

REM ----- CLEAR ANY PREVIOUS JOB OUTPUTS IF THEY EXIST
if exist ~TMP.TXT type NUL > ~TMP.TXT

REM ----- OUTPUT THE PRIMARY MONITOR INFORMATION TO A TEXT FILE
MonitorInfoView.exe /hideinactivemonitors 1 /stext ~TMP.TXT

REM ----- ISOLATE THE RESOLUTION LINE, REMOVING ALL THE OTHER LINES IN THE TEXT FILE
for /f "delims=" %%A in ('type "~TMP.TXT" ^|find.exe /i "Maximum Resolution"') do echo %%A>~TMP.TXT

REM ----- GET THE RESOLUTION NUMBERS, AND SET THEM AS VARIABLES
for /f "tokens=3,4 delims=:X " %%A in ('type "~TMP.TXT"') do set _SCREENW_=%%A& set _SCREENH_=%%B


REM >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>><<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
REM >>>>>>>>>> USER INPUT/PREFERENCES ARE ALL SET HERE [BEGIN] <<<<<<<<<<<<

REM ----- ----------------------------------------
REM ----- |COMMAND-LINE PROGRAM TO BE RUN:  FILE NAME (WITH EXTENSION)
REM ----- |
REM ----- | |IF PROG TO BE RUN IS 'CMD.EXE' (WINDOWS COMMAND PROCESSOR)
REM ----- | |ALSO READ THE NEXT COMMENTS ABOUT SETTING SWITCHES   

    set _MYPROGRAM_=upx.exe

REM ----- ----------------------------------------   
REM ----- |COMMAND-LINE PROGRAM TO BE RUN:  SWITCHES (TO BE PASSED TO THE PROGRAM)
REM ----- |
REM ----- | |YOU CAN LEAVE THIS VARIABLE WITH A BLANK VALUE IF RUNNING THE PROG WITHOUT ANY PARAMETERS
REM ----- | | 
REM ----- | | |IF THE VALUE CONTAINS THE CHARS  '|'  OR  '<'  OR  '>'  THIS BATCH WILL FAIL TO RUN !!!
REM ----- | | |
REM ----- | | | |YOU CAN APPEND EXTRA TEXT TO THE END OF THE COMMAND BY USING THE AMPERSAND CHARACTER '&'
REM ----- | | | | EXAMPLES:
REM ----- | | | | set _MYPROGRAMSWITCHES_=dir "%systemroot%\system32" /a/o/s/4 & this text will be ignored; useful for adding some inline comments.
REM ----- | | | | set _MYPROGRAMSWITCHES_=dir "%systemroot%\system32" /a/o/s/4         & this works too, and the extra blank spaces will also be ignored.
REM ----- | | | | 
REM ----- | | | | |IF PROG TO BE RUN IS 'CMD.EXE' (WINDOWS COMMAND PROCESSOR), PATH ARGUMENTS MUST POINT TO A SPECIFIC LOCATION
REM ----- | | | | |AND BE ABSOLUTE OR INCLUDE ENVIRONMENT VARIABLES, AND ALWAYS ENCLOSE PATHS IN QUOTES.
REM ----- | | | | | EXAMPLES:
REM ----- | | | | | set _MYPROGRAMSWITCHES_=type "C:\Folder With Spaces\File.txt"
REM ----- | | | | | set _MYPROGRAMSWITCHES_=type "C:\FolderWithoutSpaces\File.txt"
REM ----- | | | | | set _MYPROGRAMSWITCHES_=type "%SYSTEMROOT%\..\Folder With Spaces\File.txt"
REM ----- | | | | | set _MYPROGRAMSWITCHES_=type "%SYSTEMROOT%\..\FolderWithoutSpaces\File.txt"
REM ----- | | | | | set _MYPROGRAMSWITCHES_=type %0                                       <<<<<<<this batch file (quotes are optional; the only exception to the rule)
REM ----- | | | | | set _MYPROGRAMSWITCHES_=type "%~dp0%\..\File.txt"                     <<<<<<<goes back one Dir from this batch file
REM ----- | | | | | set _MYPROGRAMSWITCHES_=type "%~dp0%\..\SomeFolder\File.txt"          <<<<<<<goes back one Dir from this batch file and then forwards into "SomeFolder"
REM ----- | | | | | set _MYPROGRAMSWITCHES_=dir "%systemroot%\system32" /a/o/s/4          <<<<<<<displays directory listing of the System folder. NOTE: 'dir' by itself and
REM ----- | | | | |                                                                                without a specific path argument will resolve to the folder of this batch file.

    set _MYPROGRAMSWITCHES_=--best -v -o getpids-compressed.exe getpids.exe      &// original is 280 KB, will compress down to 88 KB

REM ----- ----------------------------------------
REM ----- |COMMAND-LINE PROGRAM TO BE RUN:  DIRECTORY PATH (OF THE PROGRAM)
REM ----- | 
REM ----- | |YOU CAN LEAVE THIS VARIABLE WITH A BLANK VALUE IF THE PROG IS AT SAME LOCATION AS BATCH
REM ----- | |THIS VARIABLE WILL BE IGNORED IF THE PROG IS 'CMD.EXE'
REM ----- | | 
REM ----- | | EXAMPLES:
REM ----- | | set _MYPROGRAMDIR_=.\                               <<<<<<<relative path, program and batch in same directory
REM ----- | |                                                                  dot backslash *OR* dot (trailing backslash is optional).
REM ----- | | set _MYPROGRAMDIR_=%dp0%                            <<<<<<<relative path, program and batch in same directory
REM ----- | |                                                                  same locatiion as previous but using environment variable.
REM ----- | | set _MYPROGRAMDIR_=..\                              <<<<<<<relative path, program is back one directory from batch
REM ----- | |                                                                  dot dot backslash *OR* dot dot (trailing backslash is optional).
REM ----- | | set _MYPROGRAMDIR_=%dp0%\..                         <<<<<<<relative path, program is back one directory from batch
REM ----- | |                                                                  same as location as previous but using environment variable.
REM ----- | | set _MYPROGRAMDIR_=%SYSTEMROOT%\..\My Utilities     <<<<<<<relative path, program is back one directory from the Windows folder
REM ----- | |                                                                  and then forwards into the folder 'My Utilities'
REM ----- | | set _MYPROGRAMDIR_=C:\My Utilities\                 <<<<<<<absolute path, enclosing quotes are optional; trailing backslash is optional
REM ----- | |                                                                  same location as previous

    set _MYPROGRAMDIR_=

REM ----- ----------------------------------------
REM ----- |SET THE WANTED DIMENSIONS OF THIS CONSOLE WINDOW

    set /a _WINW_=(%_SCREENW_% / 2) + 250
    set /a _WINH_=(%_SCREENH_% / 2) + 150
    set /a _WINX_=(%_SCREENW_% - %_WINW_%) / 2
    set /a _WINY_=(%_SCREENH_% - %_WINH_%) / 2

REM ----- ----------------------------------------
REM ----- |STYLE THIS CONSOLE WINDOW   !!!IMPORTANT!!!
REM ----- |
REM ----- | |IF WE DO NOT USE THE 'MODE' COMMAND HERE ALONG WITH ITS 'COLS/LINES' VALUES THEN
REM ----- | |THE POSITIONING/SIZING OF THIS WINDOW BY 'NIRCMD.EXE' FURTHER DOWN WILL NOT WORK !!!
REM ----- | |
REM ----- | | |SOME COMMANDS WILL OUTPUT A LOT OF LINES AND AND THE CONSOLE DISPLAY WILL BE TRUNCATED
REM ----- | | |RUN THIS FOR AN EXAMPLE=====>   cmd.exe dir "%systemroot%\system32" /a/o/s/4   <=====
REM ----- | | |TO SOLVE THIS PROBLEM, SET THE 'LINES' VALUE OF 'MODE' TO A VERY HIGH NUMBER
REM ----- | | |THE MAXIMUM NUMBER IS 32000 (ON MY SYSTEM); 'MODE' WILL BE IGNORED IF THE NUMBER IS HIGHER !!!   

    color 0A
    mode.com con:cols=%_SCREENW_% lines=10000

REM ----- ----------------------------------------
REM ----- |DELETE THE TEMP TEXT FILE MADE BY 'MonitorInfoView.exe'
REM ----- |COMMENT OUT THE LINE IF YOU DON'T CARE ABOUT DELETING IT

    del /f /q ~TMP.TXT 2>nul >nul

REM >>>>>>>>>> USER INPUT/PREFERENCES ARE ALL SET HERE [END] <<<<<<<<<<<<<<
REM >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>><<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<


REM ----- RUN THE TASK . . .
nircmd.exe win setsize foreground %_WINX_% %_WINY_% %_WINW_% %_WINH_%
popd

if not defined _MYPROGRAMDIR_ set _MYPROGRAMDIR_=%~dp0
if "!_MYPROGRAMDIR_!" == "." set _MYPROGRAMDIR_=%~dp0
if "!_MYPROGRAMDIR_!" == ".\" set _MYPROGRAMDIR_=%~dp0
pushd %_MYPROGRAMDIR_%
if not exist %_MYPROGRAMDIR_% goto _SKIP_
set _CONVERT_PATH_="%CD%"
set _CONVERT_PATH_=%_CONVERT_PATH_:"=%
set _MYPROGRAMDIR_=%_CONVERT_PATH_%
:_SKIP_
popd

echo ===============================================================================
echo PROGRAM ..............: !_MYPROGRAM_!
if "!_MYPROGRAM_!"=="cmd.exe" (echo PROGRAM DIR ..........: %SYSTEMROOT%\system32) else (echo PROGRAM DIR ..........: !_MYPROGRAMDIR_!)
echo PROGRAM SWITCHES .....: !_MYPROGRAMSWITCHES_!
echo ===============================================================================

if "!_MYPROGRAM_!"=="cmd.exe" (goto _PROGRAM_IS_CMD_) else (goto _PROGRAM_IS_OTHER_)

:_PROGRAM_IS_CMD_
cd /d "%SYSTEMROOT%\system32"
!_MYPROGRAMSWITCHES_!
echo. & echo. & echo.
goto _END_

:_PROGRAM_IS_OTHER_ 
cd /d "!_MYPROGRAMDIR_!"
if "%CD%\!_MYPROGRAM_!" == "%CD%\" goto _ERRORMESSAGE_
if not exist "%CD%\!_MYPROGRAM_!" goto _ERRORMESSAGE_
"!_MYPROGRAMDIR_!\!_MYPROGRAM_!" !_MYPROGRAMSWITCHES_!
echo. & echo. & echo.
goto _END_

:_ERRORMESSAGE_
cls
color 4F
echo ===============================================================================
echo PROGRAM ..............: !_MYPROGRAM_!
echo PROGRAM DIR ..........: !_MYPROGRAMDIR_!
echo PROGRAM SWITCHES .....: !_MYPROGRAMSWITCHES_!
echo ===============================================================================
echo                        ^^!^^!^^!  E R R O R  ^^!^^!^^!
echo.
echo The program has failed to run; the path set by the above values does not exist.
echo Please exit this window and check the values you have set in this batch file.
echo.
echo This batch file is located here:
echo %0
echo. & echo. & echo. & echo. & echo.

:_END_

REM ----- CLEAR VARIABLE VALUES FROM MEMORY . . .
set _PROCESS_ID_=
set _SCREENW_=
set _SCREENH_=
set _MYPROGRAM_=
set _MYPROGRAMSWITCHES_=
set _MYPROGRAMDIR_=
set _WINW_=
set _WINH_=
set _WINX_=
set _WINY_=
set _CONVERT_PATH_=

REM ----- STOP THIS CONSOLE WINDOW FROM CLOSING   !!!IMPORTANT!!! . . .
REM ----- |
REM ----- | http://superuser.com/questions/306167/how-to-prevent-the-command-prompt-from-closing-after-execution
REM ----- | | by 'kitsu.eb' (April 26, 2014)
REM ----- | | | "My solution (just tested on Win7) is to add CMD as the last line in the batch file.
REM ----- | | |  This runs a nested command prompt that inherits the environment of its parent.
REM ----- | | |  That child shell holds the batch process open until you EXIT, at which point the
REM ----- | | |  batch has no child processes and also exits."
REM ----- | Comment . . .
REM ----- | | by me
REM ----- | | | "This is a workaround. You can't use PAUSE as the last command to stop this window from closing
REM ----- | | |  because the window will terminate after you press a key. While this batch is running, if you open
REM ----- | | |  Task Manager/Process Hacker/Process Explorer you will see an extra CMD.EXE child process running
REM ----- | | |  under the parent CMD.EXE of this batch file."
cmd.exe

— derty2
সূত্র

এখানেও প্রাসঙ্গিক বিষয়বস্তু অনুলিপি করা পুরোপুরি ঠিক আছে।

— ই