তালিকা ফাইলগুলি পুনরাবৃত্তভাবে উইন্ডোজ কমান্ড প্রম্পট থেকে কেবলমাত্র পুরো পথ এবং ফাইলের আকার দেখাচ্ছে

Question

আমি একটি নির্দিষ্ট ডিরেক্টরিতে এবং এর উপ-ডিরেক্টরিগুলির (যেমন পুনরুক্তি) সমস্ত ফাইলের জন্য ফাইলের নাম (পুরো পথ সহ) এবং ফাইলের আকার সম্বলিত একটি পাঠ্য ফাইল তৈরি করার চেষ্টা করছি। আদর্শভাবে, আমি ফাইল আকারে কমা চাই না (তবে আমি তাদের জন্য বন্দোবস্ত করব!)

নিম্নলিখিত কমান্ডটি ফাইলের আকার ছাড়াই এটি করে:

dir /b /s /a:-D > results.txt

একটি উদাহরণ আউটপুট যেমন দেখতে পাবেন:

C:\Users\Martin\Pictures\Table\original\PC120013.JPG  227298
C:\Users\Martin\Pictures\Table\original\PC120014.JPG  123234
C:\Users\Martin\Pictures\Table\original\PC120015.JPG  932344

আমি মনে করি না এটি dirএকা ব্যবহার সম্ভব , যদিও আমি ভুল প্রমাণ করতে চাই। কমান্ড প্রম্পট থেকে পাওয়া কেবলমাত্র আদেশগুলি ব্যবহার করে এটি করার অন্য কোনও উপায় আছে?

Answer 1

এটি করা উচিত:

@echo off & for /f %a in ('dir /s /b') do echo %~fa %~za

এটি খুব দক্ষ নয় ... এক টন ফাইলযুক্ত ফোল্ডারগুলির জন্য এটি চালানো স্কাইচি হতে পারে, তাই এটি প্রথমে ছোট ফোল্ডারে চেষ্টা করুন।

"থেকে /?" সহায়তা পাঠ্য (আমি 'আমি' এর পরিবর্তে 'এ' ব্যবহার করেছি)

In addition, substitution of FOR variable references has been enhanced.
You can now use the following optional syntax:

%~I         - expands %I removing any surrounding quotes (")
%~fI        - expands %I to a fully qualified path name
%~dI        - expands %I to a drive letter only
%~pI        - expands %I to a path only
%~nI        - expands %I to a file name only
%~xI        - expands %I to a file extension only
%~sI        - expanded path contains short names only
%~aI        - expands %I to file attributes of file
%~tI        - expands %I to date/time of file
%~zI        - expands %I to size of file
%~$PATH:I   - searches the directories listed in the PATH
               environment variable and expands %I to the
               fully qualified name of the first one found.
               If the environment variable name is not
               defined or the file is not found by the
               search, then this modifier expands to the
               empty string

The modifiers can be combined to get compound results:

%~dpI       - expands %I to a drive letter and path only
%~nxI       - expands %I to a file name and extension only
%~fsI       - expands %I to a full path name with short names only
%~dp$PATH:I - searches the directories listed in the PATH
               environment variable for %I and expands to the
               drive letter and path of the first one found.
%~ftzaI     - expands %I to a DIR like output line

Comments

আমি এটি ব্যবহার করে একটি ছোট্ট ছিনতাই করেছি: ফাইলের নামের ফাঁকা স্থানগুলির ফাইলগুলি সঠিকভাবে নিবন্ধিত হয়নি। এটি ঠিক করার জন্য আমি নীচের "tokens=*"মতো একটি সংযোজন করেছি@echo off & for /f "tokens=*" %a in ('dir /s /b') do echo %~fa %~za

— ডন ভিনস

কিভাবে এটি একটি txtফাইল মুদ্রণ ?

— সা Saeedদ নেমতি

এটি হওয়া উচিতfor /r %a in (*) do echo %~fa %~za

— জ্যাব

@ সাeedদ নেমতি - এখানে একটি উদাহরণ >> C:\Temp\VideoList.txt- এর আগে যা কিছু প্রক্রিয়া এসেছিল তার ফলাফল ভিডিওলিস্ট নামের একটি পাঠ্য ফাইলে লেখা হয় । একটি > ব্যবহার করে ফাইলটি ওভাররাইট হবে ( এটি ইতিমধ্যে বিদ্যমান থাকলে ) এবং >> ব্যবহার করে পাঠ্য ফাইলটি ( যদি এটি ইতিমধ্যে বিদ্যমান থাকে ) শেষ পর্যন্ত নতুন ফলাফল যুক্ত করবে । যদি পাঠ্য ফাইলটি এখনও বিদ্যমান না থাকে তবে এই কমান্ডটি নির্দিষ্ট নামের সাথে একটি নতুন ফাইল লিখবে।

— ব্যবহারকারী 23715

এটি আমাকে একটি টেক্সট ফাইলে * .dwg ফাইলের ফাইলের আকার, সান্সের তালিকা দিয়েছে:@echo off & for /f "tokens=*" %a in ('dir *.dwg /s /b') do echo %~fa >>dwgfiles.txt

— সিএডি ব্লোক

Answer 2

বিকল্প # 1: ফর / আর আমার জন্য # 2 এর চেয়ে বেশি স্বজ্ঞাত।
বিকল্প # 2: ফর / এফ ব্রায়ান অ্যাডকিন্সের পরামর্শে "জায়গাগুলিতে নাম" দিয়ে সমস্যার সমাধান করে।
বিকল্প # 3: পথগুলি ডাবল উক্তি ব্যতীত আমার বেছে নেওয়া হবে।

ব্রায়ান বা অন্যান্য গুরুগুলির মধ্যে আরও মার্জিত সমাধান হতে পারে বা আরও কয়েক ডজন সমাধান সমাধান করতে সক্ষম হতে পারে তবে এই তিনটি কাজ। আমি টোকেনগুলির জন্য ব্যবহার করার চেষ্টা করেছি তবে তারপরে শিরোনাম এবং পাদচরণগুলি সরিয়ে ফেলতে হয়েছিল তাই আমি আবার # 1 এ ফিরে এসেছি। আমি একটি ছোট .bat ফাইল তৈরি করা এবং এটিকে কল করার বিষয়টিও বিবেচনা করেছি তবে এতে অন্য একটি ফাইল যুক্ত হয়েছে (যদিও এটি কোনও ফাংশন হিসাবে আরও বেশি নমনীয়তা দেয়)।

আমি এম্বেডেড স্পেস সহ ডিরেক্টরি এবং ফাইলের নামগুলি, 200+ অক্ষরের ফাইল নাম, কোনও এক্সটেনশনবিহীন একটি ফাইল নাম এবং একটি ছোট ড্রাইভের মূলের (কেবল সময়ের জন্য; কিছুটা ধীর - ঠিক যেমন ব্রায়ানের পরামর্শ অনুসারে) পরীক্ষা করেছি - তবে তারপরে উইন্ডোজ এক্সপ্লোরারে অনুসন্ধান করছে; সে কারণেই আমি সবকিছু অনুসন্ধান অ্যাপ্লিকেশন ইনস্টল করেছি)।

বিকল্প # 1: ফর / আর

সেরা (?) ব্রায়ানের সমাধান আমার পক্ষে কেন কাজ করে না তা বের করার চেষ্টা করার সময় আমি হেল্প ফরের দিকে তাকিয়ে / আর পদ্ধতির চেষ্টা করার সিদ্ধান্ত নিয়েছি। (ফাইল তৈরি করা বিকল্প # 2 এর মতোই হবে))

@echo off & for /R "c:\deletelater\folder with spaces" %A in (*.*) do echo %~fA %~zA

উদাহরণ - কাজ (পুনরাবৃত্তি প্রদর্শনের জন্য উপরের চেয়ে আলাদা ডিরেক্টরি)

@echo off & for /R "c:\deletelater" %A in (*.*) do echo %~fA %~zA
c:\DeleteLater\Name with Spaces.txt 19800676
c:\DeleteLater\NoSpacesLongName.txt 21745440
c:\DeleteLater\Folder with Spaces\2nd Name with Spaces.txt 5805492
c:\DeleteLater\Folder with Spaces\2ndNoSpacesLongName.txt 3870322
c:\DeleteLater\FolderNoSpaces\3rd Name with Spaces.txt 27874695
c:\DeleteLater\FolderNoSpaces\3rdNoSpacesLongName.txt 28726032

বিকল্প # 2: ফর / এফ

ব্রায়ান অ্যাডকিন্স প্রস্তাবিত: @echo off & for /f %a in ('dir /s /b') do echo %~fa %~za

একটি সঠিক উত্তর হ'ল:

@echo off & for /f "delims=*" %A in ('dir /s /b') do echo %~fA %~zA 

একটি সম্পূর্ণ ডিরেক্টরি সঙ্গে উত্তর দমন এবং আউটপুট (যোগ করা হয়) একটি ফাইল হল:

@echo Results on %DATE% for %CD% >> YourDirFile.txt & echo off & for /f "delims=*" %A in ('dir /s /b /a:-d') do echo %~fA %~zA >> YourDirFile.txt

দ্রষ্টব্য: "ডিলিমস = *" ফাইলের নামগুলিতে অনুমোদিত নয় এমন একটি অক্ষর নির্দিষ্ট করে।
দ্রষ্টব্য: ২ য় কমান্ড ডিরেক্টরিগুলি / a: -d এর মাধ্যমে দমন করে।
দ্রষ্টব্য: কেউ যদি বিভিন্ন ভেরিয়েবলের নাম চয়ন করে তবে ভেরিয়েবল এবং ভেরিয়েবল পরামিতিগুলির মধ্যে পার্থক্য স্পষ্ট করার জন্য ফর ভেরিয়েবল নামের বড় হাতের তৈরি করে।
দ্রষ্টব্য: ওপি কোনও ফাইলের আউটপুট চেয়েছিল বলে কেবল গ্রিনগুলির জন্য ফাইল করতে যুক্ত হয়েছে।

আমি মনে করি আমার সত্যিই ECHO এর স্থিতি পরীক্ষা করা উচিত এবং এটিকে পুনরায় সেট করা উচিত।

ইস্যু - নামগুলিতে স্পেস

ব্রায়ানের প্রস্তাবিত সমাধান ফাইল এবং ফোল্ডারের নামগুলি ফাঁকা স্থানগুলি হ্যান্ডেল করে না (কমপক্ষে আমার ভিস্তার কনফিগারেশনে নেই)।

উদাহরণ - ভুল (সীমানা ছাড়াই; ওপিতে প্রতি দমন ডিরেক্টরি অন্তর্ভুক্ত রয়েছে তবে জোর দেওয়ার জন্য ফাইলের আগে এবং পরে ফাইলের আকার সহ)

কাটা নাম এবং আকার (6 টির মধ্যে 4 টি ফাইল ভুল):

@echo off & for /f %A in ('dir /s /b /a:-d') do echo %~zA %~fA %~zA
 C:\DeleteLater\Name
21745440 C:\DeleteLater\NoSpacesLongName.txt 21745440
 C:\DeleteLater\Folder
 C:\DeleteLater\Folder
 C:\DeleteLater\FolderNoSpaces\3rd
28726032 C:\DeleteLater\FolderNoSpaces\3rdNoSpacesLongName.txt 28726032

উদাহরণ - সঠিক (স্ক্রিনে নোট আউটপুট, ফাইলের সাথে সংযুক্ত করা হয়নি)

@echo off & for /f "delims=*" %A in ('dir /s /b /a:-d') do echo %~fA %~zA
C:\DeleteLater\Name with Spaces.txt 19800676
C:\DeleteLater\NoSpacesLongName.txt 21745440
C:\DeleteLater\Folder with Spaces\2nd Name with Spaces.txt 5805492
C:\DeleteLater\Folder with Spaces\2ndNoSpacesLongName.txt 3870322
C:\DeleteLater\FolderNoSpaces\3rd Name with Spaces.txt 27874695
C:\DeleteLater\FolderNoSpaces\3rdNoSpacesLongName.txt 28726032

বিকল্প # 3: ফর্মিলস (উদ্ধৃতি ইস্যু)

এই সমাধানটি ফোরফিল ডকুমেন্টেশন ( forfiles /?) এর শেষ দুটি উদাহরণ থেকে সরাসরি ।

FORFILES /S /M *.doc /C "cmd /c echo @fsize"
FORFILES /M *.txt /C "cmd /c if @isdir==FALSE notepad.exe @file"

এই উদাহরণগুলির সংমিশ্রণ এবং একটি ফাইলের লিখনের উত্তর পাওয়া যায় (প্রায়):

forfiles /s  /c "cmd /c if @isdir==FALSE echo @path @fsize" >>ForfilesOut.txt

লক্ষ্য করুন যে পথটি আউটপুটে উদ্ধৃতিতে রয়েছে।
কিনা কোন ব্যাপার না echo onবা echo offটগল করা হয়।
প্রতিটি ডিরেক্টরি পৃথক করে একটি ফাঁকা লাইন যুক্ত করা আইএফের একটি তুচ্ছ এক্সটেনশন হবে।

সতর্কতা : মুখোশ ব্যবহার করে/m *.*এক্সটেনশন ছাড়াই ফাইলগুলি ফিরবে না (উদাহরণস্বরূপ শেষ ফাইলের মতো)!

একদিকে : এটি প্রতিটি ডিরেক্টরিতে কেবল সেই ডিরেক্টরিটির বিষয়বস্তু সহ একটি ফাইল লিখে দেয়:
forfiles /s /c "cmd /c if @isdir==FALSE echo @path @fsize >>ForfilesSubOut.txt"ওপি যা চায় তা নয় তবে কখনও কখনও সহজও হয়।

উদাহরণ - কাজ (তবে উদ্ধৃতিতে পুরোপথ সহ)

forfiles /s  /c "cmd /c if @isdir==FALSE echo @path @fsize"

"c:\DeleteLater\Name with Spaces.txt" 19800676
"c:\DeleteLater\NoSpacesLongName.txt" 21745440
"c:\DeleteLater\Folder with Spaces\2nd Name with Spaces.txt" 5805492
"c:\DeleteLater\Folder with Spaces\2ndNoSpacesLongName.txt" 3870322
"c:\DeleteLater\FolderNoSpaces\3rd Name with Spaces.txt" 27874695
"c:\DeleteLater\FolderNoSpaces\3rdNoSpacesLongName.txt" 28726032
"c:\DeleteLater\MoreFiles\A really really long file name that goes on and on 123456789 asdfghjkl zxcvnm qwertyuiop and still A really really long file name that goes on and on 123456789 qwertyuiop and still further roughly 225 characters by now.txt" 447
"c:\DeleteLater\MoreFiles\New Text Document no extension" 0

এই উদাহরণে একটি সুপার দীর্ঘ দীর্ঘ নাম এবং একটি এক্সটেনশন ছাড়াই একটি ফাইল নাম সহ একটি অতিরিক্ত ডিরেক্টরি অন্তর্ভুক্ত।

ইস্যু: উদ্ধৃতিগুলিতে পথ

সুতরাং, ওপি উদাহরণ অনুসারে অবাঞ্ছিত (?) উদ্ধৃতিগুলি সরানোর এবং বিকল্প # 3: ফোরফিলগুলি সংরক্ষণ করার কী সহজ উপায় আছে? (অলঙ্কৃত প্রশ্ন: উদ্ধৃতিগুলি কোনও বৈশিষ্ট্য বা কোনও ত্রুটি?)

Answer 3

আমি বুঝতে পারি এটির জন্য অতিরিক্ত উত্সাহের প্রয়োজন , তবে আপনি এসএফকে ইউটিলিটি ব্যবহার করে মোটামুটি সাফল্যের সাথে এটি অর্জন করতে পারেন :

sfk cwd +run -yes "sfk list -size -tab $qfile +toclip"

sfk fromclip > C:\_temp\sfk_list_output.txt

( এখানে এসএফকে কমান্ড চেইন ব্যবহার করে আমি পন্থাটি পেয়েছি )

Answer 4

powershell "dir | select name,length"

এটি ওপিএসের প্রশ্নে প্রতারণামূলক হতে পারে। যাইহোক, আধুনিক উইন্ডোজ-ভিত্তিক সিস্টেমে প্রশ্নটি এখন আর প্রাসঙ্গিক নয়। যৌক্তিক লিঙ্কটি আঁকতে সাহায্য করার জন্য দির ওরফে ব্যবহার করা হয়েছিল।

Comments

আমি এটি চেষ্টা করেছি (উইন্ডোজ)) এটি চালাতে 30 সেকেন্ডেরও বেশি সময় নিয়েছে (20 এন্ট্রি সহ একটি ডিরেক্টরিতে) এবং এটি সাব-ডিরেক্টরিতে নেমে আসে না।

— স্কট

পুনরাবৃত্তি করতে দয়া করে এটিকে পরিবর্তন করুন: powershell "Get-ChildItem -Recurse| select name,length"

— জিওরজিওমুগনাইনি

Answer 5

নীচে আমি এমন মিস্ক ভিডিও ফাইলগুলি সনাক্ত করতে ব্যবহার করেছি যা একটি নেটওয়ার্ক ড্রাইভে অনেক বেশি জায়গা নিয়েছিল এবং স্থানীয় পিসিতে কোনও পাঠ্য ফাইলে ফলাফল লিখতে পারে।

আমি তিনটি কারণে আমার নিজের কিছুটা দেরি উত্তর পোস্ট করছি। এক, আমি সংক্ষিপ্ত উত্তর পছন্দ করি। দুই, স্ক্রিপ্টের এই একক লাইনটি নেটওয়ার্ক জুড়ে আমার জন্য একাধিক সেটিংসে কাজ করেছে। তিন, ব্রানএডকিনসের উত্তরের অধীনে ডন ভিন্সের সম্ভাব্য অস্পষ্ট মন্তব্য অনুসারে, টোকেনগুলি ব্যবহার করে তাদের ফাঁকা জায়গাগুলির ফাইল নাম থেকে সমস্যাগুলি বাইপাস করতে পারে।

for /f "tokens=*" %%a in ('dir H:\*.mov H:\*.avi H:\*.wmv H:\*.mp4 /s /b') do echo %%~fa %%~za >> C:\Temp\VideoList.txt

আমি লক্ষ্য করেছি যে খুব দীর্ঘ ফাইল-পাথ / ফাইল-নাম (কয়েকশ অক্ষর) ত্রুটিও ঘটায় তবে অনুসন্ধানগুলি সেগুলিতে আটকাবে না। তবে আপনার লক্ষ্য (গুলি) এর জন্য পথটি পুরোপুরি অন্বেষণ করা যায় না। একবার লক্ষ্য করা গেলে, আপনি এই ত্রুটিটি দূর করতে ফোল্ডার কাঠামোর গভীরে শুরু করে ক্ষতিপূরণ দিতে পারবেন।

এই পৃষ্ঠাটি ss64 ব্যবহারের একটি খুব ভাল উপস্থাপনা করেছেন Dir কমান্ড সব সুইচ অনেক সুইচ সমন্বয় তালিকা, এবং সঠিক বাক্য গঠন বিভিন্ন দরকারী উদাহরণ দেখাচ্ছে। এটি বিভিন্ন স্ট্যাক এক্সচেঞ্জের সম্প্রদায়ের মতো বিস্তৃত নয় তবে একবার আপনি কমান্ড লাইন / ব্যাচের স্ক্রিপ্টিংয়ের সাথে স্বাচ্ছন্দ্য বোধ করলে উপস্থাপনার একটি নির্দিষ্ট স্পষ্টতা থাকে।

Answer 6

আমি নিম্নলিখিত কমান্ড সহ এটি পৌঁছেছি:

(for /R "\path\to\directory\" %A in (*.*) do echo %~fA %~zA) | findstr /v "echo"

ফলাফল:

D:\Users\Natasha>(for /R ".\" %A in (*.*) do echo %~fA %~zA) | findstr /v "echo"


D:\Users\Natasha\Flowers_ (12).jpg 118886

D:\Users\Natasha\SomeFolder\data.txt 1241

D:\Users\Natasha\SomeFolder\CS\Counter-Strike_1.6.exe 272645624

পিএস এটি বিলআর (বিকল্প # 1) এর উত্তরের ভিত্তিতে তৈরি। তবে আমার ক্ষেত্রে এটি ঝুলছে @echo off।

Answer 7

আমি "ডু" কমান্ডটি বেশ সহায়ক বলে মনে করি এবং এটি উইন্ডোজ এবং ইউনিক্স উভয় ক্ষেত্রেই কাজ করে (উইন্ডোজ পিসি থেকে লিনাক্স ওয়েব সার্ভারে প্রচুর ডেটা স্থানান্তর করার সময় সমস্ত ফাইল অনুলিপি করা হয়েছিল কিনা তা পরীক্ষা করতে এটি ব্যবহৃত হয়েছিল):

du -ah "C:\your_dir" > "C:\file_list.txt"

আউটপুট:

15  C:\your_dir/.htaccess
608 C:\your_dir/folder/hello.txt
1.0 C:\your_dir/folder/subfolder/test.txt
1.0 C:\your_dir/folder/subfolder
1.2M    C:\your_dir/folder/world.txt
1.2M    C:\your_dir/folder
9.0 C:\your_dir/no_file_ending
11  C:\your_dir/sample document 1.txt
684K    C:\your_dir/sample document 2 - äöüßÄÖÜáà.txt
1.9M    C:\your_dir

তবে আমি কেবল নোটপ্যাডে বিশেষ অক্ষরগুলি সঠিকভাবে দেখতে পেলাম নোটপ্যাড ++ এ নয় (অবশ্যই কিছু এএনএসআই / ইউটিএফ -8 এনকোডিং জিনিস হওয়া উচিত, ঠিক এখন বিশ্লেষণ করার সময় নেই)) এছাড়াও আমি ফাইলের নামের পরে আকারটি প্রদর্শনের কোনও সমাধান খুঁজে পাইনি। বাইট বা কিলোবাইটে আকার প্রদর্শন করতে "এইচ" এর পরিবর্তে "বি" বা "কে" বিকল্পগুলি ব্যবহার করুন। আমি যে ফোল্ডারটি বিশ্লেষণ করতে চাই তার বাইরে কমান্ড চালানোর সময় আমার কিছুটা সমস্যা হয়েছিল। সুতরাং সর্বোত্তমভাবে উভয়ই সঠিক ডিরেক্টরিতে কমান্ডটি প্রবেশ করান (এই উদাহরণে "সি: \ আপনার_ডির") এবং কমান্ডটিতে এটি উল্লেখ করে।

Answer 8

বি দির / বি / এস / এ: -ডি> ফলাফল.txt এ ছাড়ুন এবং ফলাফলগুলি দেখতে যেমন হওয়া উচিত (যেমন দির / এস / এ: -ডি> ফলাফল.txt):

ড্রাইভ এইচ এর ভলিউম ফাইলগুলি ভলিউম সিরিয়াল নম্বরটি C9EB-112E

এইচ ডিরেক্টরি: \ ফাইল

09/29/2014 11:36 অপরাহ্ন 0 টেস্টিং .txt 1 ফাইল (গুলি) 0 বাইট

এইচ এর ডিরেক্টরি: \ ভিডিও \ ক্রিয়া \ কমিক্স

10/06/2012 09:51 এএম 184,740 file1.txt 07/20/2012 06:21 এএম
864,832 file2.txt 08/31/2009 08:47 পিএম 606,638 file3.txt 08/31/2009 09:07 পিএম 160,320 ফাইল4 .txt

Comments

এটি মূল প্রশ্নের উত্তর নয় । এটি ওপি যে আউটপুট চেয়েছিল তা উত্পাদন করে না।

— DavidPostill

Answer 9

where * /t  

অতিরিক্ত জটিল না হয়ে, এটি পছন্দসই আউটপুট উত্পাদন করা উচিত। এটি ওপি যা চেয়েছে তার চেয়ে একটু বেশি দেবে, তবে আমি ভেবেছিলাম এটি উল্লেখ করার মতো। বর্তমান ছাড়া অন্য কোনও ডিরেক্টরি নির্দিষ্ট করতে / আর স্যুইচ যুক্ত করুন।

Comments

আমি চেষ্টা করার সাথে সাথে আপনার উত্তরটি আপডেট করে তা নিশ্চিত করার বিষয়টি বিবেচনা করুন এবং ERROR: Invalid syntax. Value expected for '/r'ড্রয়িং বোর্ডে ফিরে গিয়ে সঠিক বাক্য গঠন দেওয়ার বিষয়ে বিবেচনা করুন এবং সঠিক উত্তর দিয়ে আপনার উত্তরটি সম্পাদনা করুন।

— পিম্প জুস আইটি

মান প্রবেশ করানো বিবেচনা করুন ... / আর হ'ল ডিরেক্টরি স্যুইচ, যদি আপনি এটি ছেড়ে দেন তবে বর্তমান ডিরেক্টরিতে ডিফল্ট হয়।

— someguy

“এটি ওপি যা চেয়েছে তার চেয়ে কিছু বেশি দেবে”। তুমি কি মজা করছ?  where /?বলে, "ডিফল্টরূপে অনুসন্ধানটি বর্তমান ডিরেক্টরি বরাবর এবং PATH এনভায়রনমেন্ট ভেরিয়েবলের দ্বারা নির্দিষ্ট পথগুলিতে করা হয় । "- সুতরাং আপনার where * /tকমান্ডটি প্রতিটি ফাইলের মধ্যে C:\Windows\System32, কয়েকটি উপ- C:\Program Filesডিরেক্টরি এবং এর মধ্যে থাকা প্রতিটি ডিরেক্টরিকে তালিকাভুক্ত করে PATH। আমার জন্য, এটি 3000 লাইনের বেশি ছিল। আপনার উত্তর যুক্তিসঙ্গত করতে দয়া করে সম্পাদনা বিবেচনা করুন। পিএস ছাড়া  /R, এটি পুনরাবৃত্ত হয় না।

— স্কট

যেখানে / আর *। * আমার জন্য কাজ করেছে। / আর। নির্দিষ্ট স্থান থেকে পুনরাবৃত্তভাবে অনুসন্ধান করতে বলে (এই ক্ষেত্রে এটির বর্তমান ডিরেক্টরি)। * * * মিলের প্যাটার্ন। সুতরাং WHERE / R% USERPROFILE% * .ডোক্স ব্যবহারকারীর ফোল্ডারে সমস্ত শব্দ ফাইল প্রদর্শন করবে। (এই মন্তব্যে with সহ * পালাতে হবে)

— DHW