(কোনও মন্তব্যে ফিট করার জন্য এটি দীর্ঘ সময় থেকে আলাদা উত্তর হিসাবে পোস্ট করা)
আসল স্ক্রিপ্টের জন্য @ ম্যাথিউইউরেগলারে ক্রেডিট
এটি 10.12.6 এ কাজ করেছে এবং এটি মূল স্ক্রিপ্টের একটি সামান্য পরিবর্তন (@ আমার নিজের তদন্ত শেষ করার পরে @ চার্লিগোরিচানজের মন্তব্য দেখুন):
set textToSearchForInProcessName to "Not Responding"
-- Run Activity Monitor
tell application "Activity Monitor" to activate
tell application "System Events" to tell process "Activity Monitor"
-- Wait for the Activity Monitor window to open
repeat until (exists window 1)
delay 1
end repeat
--display notification "Window appeared"
-- Wait for the Menubar to be present
repeat until (exists menu 1 of menu bar item "View" of menu bar 1)
delay 1
end repeat
--display notification "Menubar appeared"
-- Make sure View -> My Processes is selected
click menu item "My Processes" of menu 1 of menu bar item "View" of menu bar 1
-- Click the 'CPU View' button ( **1 )
click radio button 1 of radio group 1 ¬
of group 2 of toolbar 1 ¬
of window 1
-- Working with the list of processes
tell outline 1 of scroll area 1 of window 1
-- Looking for Not responding process
set notResponding to rows whose value of ¬
first static text contains textToSearchForInProcessName
repeat with aProcess in notResponding
-- For each non responding process retrieve the PID
set pid to value of text field 1 of aProcess -- ( **2 )
-- Kill that process using pid
if pid is not "" then do shell script ("kill -9 " & pid)
end repeat
end tell
end tell
** 1
ম্যাকোএস 10.12.x এ, সরঞ্জামদণ্ডে একটি অতিরিক্ত
আইকনরয়েছেযার কারণে বোতামগুলির সেট (সিপিইউ, মেমরি, শক্তি ইত্যাদি) এর group 2 of toolbar 1পরিবর্তে রয়েছেgroup 1 of toolbar 1। এই আইকনের অনুপস্থিতিতে (আমি পুরানো ম্যাকোস সংস্করণগুলিতে নিশ্চিত নই), আমার বিশ্বাস সিপিইউ ইত্যাদির বোতামগুলি থাকবেgroup 1 of toolbar 1
** 2
আপনি যদি ক্রিয়াকলাপের পিআইডি কলামটিকে কোনও আলাদা অবস্থানে টেনে নিয়ে থাকেন তবে এটি প্রয়োগ হয়। আমি এই লাইনে পিআইডি কলামটি বামতম অবস্থানে টেনে নিয়েছি, আমাকে সূচকটি এখানে পরিবর্তন করতে হয়েছিল1:
set pid to value of text field 1 of aProcess
কলামগুলি বামদিক থেকে শুরু করা হয়েছে, ১ থেকে শুরু করে So