9

এই দুটি নির্দিষ্টভাবে পার্থক্য করার কি আছে?

আমি বুঝতে পারছি আমি সূচনা স্ক্রীন এ একটি টাস্কবার বা পাওয়ার বাটন খুঁজতে পারেন, কিন্তু আমি বুদ্ধিমান যে আসলে প্রদর্শন 8.1 আপডেট 1. যে কোন জায়গায় আছে কিনা আরও আগ্রহী আমি জানি মাইক্রোসফট হয়েছে এই পৃষ্ঠার কিন্তু সনাক্ত এটি হবে একটি কর্মসূচি উপায় দুর্দান্ত, বিশেষত সর্বশেষতম আইএসওগুলিতে আপডেট স্লিপস্ট্রিমেড রয়েছে।

যতদুর আমি বলতে পারেন, আউটপুট verএবং wmic osউইন্ডোজ 8.1 এবং Windows 8.1 মধ্যে একই। আপডেট 1, এবং সিস্টেম বৈশিষ্ট্যগুলি এখনও উইন্ডোজ 8.1 প্রতিবেদন করে।

windows-8.1

— Ernie
সূত্র

1

আপনি না। "আপডেট 1" থাকা নির্দিষ্ট উইন্ডোজ আপডেট নোলেবসটি ইনস্টল করা আছে কিনা তা আপনাকে পরীক্ষা করতে হবে। আমার হাতে নম্বরটি খুব ভাল ডকুমেন্টেড নেই।

— রামহাউন্ড 19

2

@ র্যামহাউন্ড এটি কেবলমাত্র 8.1.1 থেকে আপগ্রেড হওয়া সিস্টেমগুলির জন্য কাজ করে। । । এমএসডিএন-তে আইএসওগুলি এখন আপডেট সহ উইন্ডোজ 8.1, এবং তাদের ইতিহাসে উইন্ডোজ আপডেট নেই। । ।

— আর্নি

2

@ and31415 বিল্ড সংস্করণটি verআউটপুট (6.3.9600) এ প্রতিবেদন করা হয়েছে এবং উভয়ের ক্ষেত্রে একই the আমি যে সমস্যাটি সমাধান করার চেষ্টা করছি তা হ'ল আমাদের ল্যাবটিতে আমাদের কী সিস্টেম রয়েছে এবং কী ওএস চলছে they । । সম্পূর্ণ পরীক্ষার কভারেজের জন্য, আমরা 8.1 এবং 8.1 উভয়ই আপডেট 1

— আর্নি

2

@ and31415 আমার আরও স্পষ্ট হওয়া উচিত ছিল। উভয় verআউটপুট এবং রেজিস্ট্রি তথ্য অভিন্ন। ডাব্লুএমআই / ফাইন্ডস্টার পদ্ধতিটি মনে হয় এটি কার্যকর হবে (এমনকি নতুন আইএসও থেকে ইনস্টল করা সিস্টেমেও) যদিও এটি পাপ হিসাবে কুৎসিত (বিশেষত যেহেতু এটি মূলত একটি চেকের পরে দ্বিতীয় চেক হতে চলেছে ver)। । । উত্তর হিসাবে পোস্ট করুন এবং আমি এটি গ্রহণ করব। । ।

— আর্নি

2

@ র‌্যামাউন্ড আমি বুঝতে পারি আপনি এটি আপডেট করতে পারবেন না, তবে আমরা এখানে সফ্টওয়্যার পরীক্ষা করেছি এবং ঠিক আমাদের যেমন এমন ব্যবহারকারীরা পেয়েছি যারা এখনও সার্ভিস প্যাক ছাড়াই এক্সপি চালাচ্ছেন, আমরা ধরে নিই যে আমাদের আপডেট না করেই 8.1 ব্যবহারকারীর ব্যবহারকারী থাকবেন। আমাদের সফ্টওয়্যারটি সমস্ত পরিবেশে কাজ করে তা নিশ্চিত করার জন্য আমাদের বিস্তৃত কভারেজ প্রয়োজন এবং সিস্টেমগুলির প্রশস্ততা আমাদের কাছে গুরুত্বপূর্ণ।

— আর্নি

6

সম্ভাব্য সমাধান

নীচে কয়েকটি ব্যাচের স্ক্রিপ্ট রয়েছে যা অপারেটিং সিস্টেমটি উইন্ডোজ 8.1 কিনা কেবি 2919355 এর সাথে বা ছাড়াই তা পরীক্ষা করতে পারে । প্রস্থান কোড নিম্নলিখিতগুলির মধ্যে একটি হবে:

0: উইন্ডোজ 8.1
1: উইন্ডোজ 8.1 আপডেট (KB2919355 ইনস্টল)
2: উইন্ডোজ 8.1 নয়

ব্যাচের স্ক্রিপ্ট এ - আপডেট চেক

এটি সবচেয়ে নির্ভরযোগ্য উপায়। অপারেটিং সিস্টেমটি উইন্ডোজ 8.1 এর সাথে সংস্করণটির সাথে তুলনা করে স্ক্রিপ্টটি প্রথম পরীক্ষা করে 6.3.9600। তারপরে KB2919355 আপডেটটি ইতিমধ্যে ইনস্টল করা আছে কি না তা যাচাই করার জন্য সমস্ত ইনস্টল করা আপডেটগুলি অনুসন্ধান করা হয়।

@echo off

for /f "usebackq tokens=2 delims==" %%G in (
`wmic os get version /value ^| findstr /c:"="`
) do set version=%%~G

if not "%version%" == "6.3.9600" exit /b 2

wmic qfe get hotfixid | findstr /i /c:"KB2919355" >nul
set /a errorlevel=%errorlevel% ^^ 1

exit /b %errorlevel%

ব্যাচের স্ক্রিপ্ট বি - সংস্করণ পরীক্ষা তৈরি করুন

বিকল্প হিসাবে আপনি উইন্ডোজ বিল্ড সংস্করণটি চেক করতে পারেন, এটি প্রথম স্ক্রিপ্টের চেয়ে দ্রুততর কারণ আপনাকে সমস্ত আপডেট গণনা করার দরকার নেই। যেহেতু এটি একটি রেজিস্ট্রি মান ব্যবহার করে তাই এটি নির্ভরযোগ্য নাও হতে পারে।

@echo off

for /f "usebackq tokens=2 delims==" %%G in (
`wmic os get version /value ^| findstr /c:"="`
) do set version=%%~G

if not "%version%" == "6.3.9600" exit /b 2

for /f "tokens=4 delims=. " %%G in (
'"reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v "BuildLabEx" | findstr /i /c:"REG_SZ" "'
) do set /a build=%%~G

if %build% geq 17031 exit /b 1
exit /b 0

ব্যাচ স্ক্রিপ্ট সি - বিল্ড সংস্করণ চেক (ইন্টারনেট এক্সপ্লোরার)

ঠিক আগের স্ক্রিপ্টের মতোই, এখানে ইন্টারনেট এক্সপ্লোরার (আইই) সংস্করণটি পরিবর্তিতভাবে পরীক্ষা করা বাদে ধারণাটি একই রকম।

@echo off

for /f "usebackq tokens=2 delims==" %%G in (
`wmic os get version /value ^| findstr /c:"="`
) do set version=%%~G

if not "%version%" == "6.3.9600" exit /b 2

for /f "tokens=3,6 delims=. " %%G in (
'"reg query "HKLM\SOFTWARE\Microsoft\Internet Explorer" /v "svcVersion" | findstr /i /c:"REG_SZ" "'
) do set /a major=%%~G & set /a build=%%~H

if %major% equ 11 if %build% geq 17031 exit /b 1
if %major% geq 12 exit /b 1
exit /b 0

দ্রষ্টব্য স্ক্রিপ্টটি ধরে নিয়েছে যে কোনও উইন্ডোজ 8.1 সিস্টেমে আপডেটের KB2919355 ইনস্টল থাকা 12 ই এর তুলনায় উচ্চতর বা 12 এর সমান সংস্করণ পাওয়া যাবে।

উইন্ডোজ আরটি 8.1, উইন্ডোজ 8.1, এবং উইন্ডোজ সার্ভার 2012 আর 2 এর ভবিষ্যতের সমস্ত সুরক্ষা এবং অনিরাপদ আপডেটগুলির জন্য এই আপডেটটি ইনস্টল করা প্রয়োজন। ভবিষ্যতের আপডেটগুলি অব্যাহত রাখতে আপনি এই আপডেটটি আপনার উইন্ডোজ আরটি 8.1, উইন্ডোজ 8.1, বা উইন্ডোজ সার্ভার 2012 আর 2-ভিত্তিক কম্পিউটারে ইনস্টল করার পরামর্শ দিচ্ছেন।

_{উত্স: উইন্ডোজ আরটি 8.1, উইন্ডোজ 8.1, এবং উইন্ডোজ সার্ভার 2012 আর 2 আপডেট: এপ্রিল 2014}

উপরের দিক থেকে, এটি ভাবা যুক্তিসঙ্গত যে কোনও নতুন আইই সংস্করণটির আপডেটটি পূর্বশর্ত হিসাবে প্রয়োজন, ঠিক যেমন উইন্ডোজ ভিস্তার আইপি 9 ইনস্টল করতে এসপি 2 প্রয়োজন ।

— and31415
সূত্র

1

আমি খুশি যে আইই 11 সংস্করণটি পরীক্ষা করার বিষয়ে আমার ধারণাটি একটি সম্ভাব্য সমাধান ছিল।

— রামহাউন্ড

@ রামহাউন্ড আমি পুরানো স্ক্রিপ্টটি উন্নত করেছি। আইই সংস্করণটি পরীক্ষা করে নেওয়ার কিছু ক্যাভেট রয়েছে এবং আমি এটি পরিষ্কার করার জন্য উত্তর আপডেট করেছি।

— 31415

3

BuildLabExস্ট্রিং পার্স করুন

reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" | findstr BuildLabEx

এবং সংখ্যাটি যদি 17031ব্যবহারকারীদের চেয়ে বড় হয় তবে আপডেট 1 ইনস্টল করা আছে।

— magicandre1981
সূত্র

BuildLabআপডেট করা হয় না; BuildLabExeহয়।

— জেরোয়েন ওয়েয়ার্ট প্লুইমার্স

@ Magandandre1981 - এই ক্যোয়ারী স্ক্রিপ্ট চেক করে যা ঠিক তাই।

— রামহাউন্ড

প্রাথমিক বাক্যটি নিয়ে কথা হয় BuildLab। আমার মন্তব্য দুটির মধ্যে পার্থক্য ব্যাখ্যা করে, কারণ এর স্ক্রিপ্টটির ডিফল্ট 100% পাঠ্য ম্যাগনিফিকেশনের Exঅংশটি BuildLabExলুকানো রয়েছে।

— জেরোয়েন ওয়েয়ার্ট প্লাইমার্স

0

আমরা WuInstall ( http://www.wuinstall.com ) নামে একটি কমান্ড লাইন ইউটিলিটি ব্যবহার করি যা প্যাচিংয়ের আশেপাশে কিছু দরকারী কাজ করে, এর মধ্যে ব্যাচ স্ক্রিপ্টগুলি আপডেটগুলি যাচাই করা হয় তা পরীক্ষা করে সক্ষম করে

সমস্ত ইনস্টল করা আপডেটগুলি দেখানোর জন্য কমান্ড লাইন

WUInstall.exe / অনুসন্ধান / মানদণ্ড "IsInstalled = 1" / অফলাইন

কোনও নির্দিষ্ট কেবি ইনস্টল করা আছে কিনা তা পরীক্ষা করতে (অনেকগুলি ফিল্টারিং বিকল্প রয়েছে) আপনি যাচাই করতে পারেন:

WUInstall.exe / অনুসন্ধান / মানদণ্ড "IsInstalled = 1" / অফলাইন / ম্যাচ "KB982214"

ইউটিলিটি কিছু কমান্ড লাইন আউটপুট দেয়, যা একটি এক্সএমএল ফাইলের সাথে / xMLout নামক বিকল্পের সাথে পুনঃনির্দেশিত করা যেতে পারে বা যেমন> আউট. টেক্সট সহ কোনও ফাইলে পুনঃনির্দেশিত হতে পারে

— MacDonkey
সূত্র

-1

আমি উইন্ডোজটিতে কেবল একটি "উইনস্টোর" ফোল্ডারটি পরীক্ষা করে দেখি কারণ আমি লক্ষ্য করেছি যে এটি উইন্ডোজের সমস্ত সংস্করণে একটি স্পষ্ট পার্থক্য।

এমনকি এটি দেখতে উইন্ডস্টোর কমান্ড চালাতে পারে।

আরইএম সিমুলেটিং ওএস চেক: ইনস্টল করুন সি: সিডি \ উপস্থিত থাকলে "সি: \ উইন্ডোজ \ উইনস্টোর" যান WIN8

: উইন 8 একটি উইন 8 মেশিনের জন্য স্মরণীয় কোড

— PowerTrip
সূত্র

1

আমি অনুমান করছি আপনি এটি উইন্ডোজ ৮ শ্লোক নন-উইন্ডোজ ৮ এর জন্য বলছেন। এই প্রশ্নটি বিশেষত

— উইন ৮.১

উইন্ডোজ 8.1 আপডেট থেকে উইন্ডোজ 8.1 আপডেট 1 কে কীভাবে আলাদা করা যায়?

সম্ভাব্য সমাধান

ব্যাচের স্ক্রিপ্ট এ - আপডেট চেক

ব্যাচের স্ক্রিপ্ট বি - সংস্করণ পরীক্ষা তৈরি করুন

ব্যাচ স্ক্রিপ্ট সি - বিল্ড সংস্করণ চেক (ইন্টারনেট এক্সপ্লোরার)