কোনও গণনা শেষ হয়ে গেলে আমি কী এক্সেল বীপ তৈরি করতে পারি?

13

এক্সেলে আমার এই সত্যিই দীর্ঘ গণনা আছে। আমি পর্দা থেকে আমার মনোযোগ সরিয়ে এবং আমার ডেস্কে কিছু করতে চাই, তবে যখন হিসাব শেষ হবে তখন সতর্ক হতে হবে।

কোন ধারনা?

microsoft-excel

— এলিয়কে
সূত্র

1

হিসাবটা ঠিক কীভাবে করছেন? এটি যদি ভিবিএতে থাকে তবে ভিবিএর "বিপ" পদ্ধতিটি ব্যবহার করবেন না কেন ? আপনি ইতিমধ্যে কি চেষ্টা করেছেন?

— ʜιᴇcʜιᴇ007

2

@ techie007 ভিবিএ নয় বৃহত্তর এক্সেল স্প্রেডশিটে কেবল ফাংশন।

— ইলিয়াহু

1

তবুও আপনি সম্ভবত বিপ ফাংশনটি ব্যবহার করতে পারেন, বিশেষত যদি আপনি এসএস আসলে "সূত্রগুলি" পরিবর্তে গণনা করতে "ফাংশন" ব্যবহার করছেন। তবে "আপনি কীভাবে" এটি ব্যবহার করতে পারবেন তা আপনার স্প্রেডশিট কীভাবে কাজ করে তার উপর নির্ভর করে, যা আমরা জানি না। আপনি কি কেবল কোনও ঘরে কোনও মান টাইপ করছেন এবং তারপরে এটি শেষ হওয়ার জন্য সত্যিই দীর্ঘ সময় অপেক্ষা করতে হবে, বা আপনি ঘরগুলি পূরণের পরে গণনা শুরু করতে একটি বোতামটি চাপছেন? আপনি যদি ভিবিএ সম্পাদক খোলার জন্য এফ 11 এ আঘাত করেন তবে সেখানে কি গুচ্ছ কোড রয়েছে?

— ʜιᴇcʜιᴇ007

@ techie007 আমি সূত্র ব্যবহার করছি। আমি একগুচ্ছ কাজের পরে এফ 9 টিপবো এবং অপেক্ষা করতে হবে।

— এলিয়াহু

আপনি আপনার গণনা অন্যভাবে করতে হবে। আপনি যা করছেন তা যদি সম্ভব না হয় তবে আপনি যা করছেন তা

— এক্সেলকে

21

ঠিক আছে, চেষ্টা করার জন্য কিছু (নির্দেশাবলী এক্সেল 2007 বা আরও নতুন ধরে নেওয়া):

আপনার কাজের বই খুলুন।
এটিকে ম্যাক্রো-সক্ষম সক্ষম এসএস ( .XLSM) হিসাবে সংরক্ষণ করুন ।
ভিবিএ কোডিং উইন্ডোটি খুলতে Alt-F11 চাপুন।
ভিবিএপ্রজেক্ট ( yourbook.xlsm) টি ডান ক্লিক করুন এবং সন্নিবেশ → মডিউলটি চয়ন করুন।
সদ্য নির্মিত "মডিউল 1" খুলুন।
মডিউলটিতে এই স্নিপেটটি পেস্ট করুন:
```
Sub Auto_Open()
    Application.OnKey "{F9}", "F9Handler"
End Sub
```
এটি প্রতিবার এসএস খোলার সাথে সাথে F9 কীটি পুনরায় নিয়োগ দেওয়া হবে। আপনি যখন F9 চাপবেন তখন এটি F9Handlerসাধারণ গণনার পরিবর্তে চলবে ।
মডিউলটিতে, এই স্নিপেটটি পেস্ট করুন:
```
Sub F9Handler()
    Application.Calculate
    Beep
End Sub
```
আপনি এফ 9 তে আঘাত করলে এখন এটিই চলবে। প্রথম লাইনটি চালায় Application.Calculate(যা এফ 9 সাধারণত সম্পাদন করে) এবং তারপরে বিপস।
সবকিছু সংরক্ষণ করুন।
বন্ধ এক্সেল
(পুনরায়) আপনার তৈরি এক্সএলএসএম খুলুন।
লাভ। :)

দ্রষ্টব্য: ম্যাক্রো (গুলি) প্রত্যাশিতভাবে চালানো নিশ্চিত করতে আপনাকে সম্ভবত ম্যাক্রো সক্ষম করতে হবে এবং / অথবা নথিকে একটি "বিশ্বাসযোগ্য" নথি তৈরি করতে হবে।

অধিক তথ্য:

— Ƭᴇcʜιᴇ007
সূত্র

5

অন্যরা উল্লিখিত হিসাবে, beepভিজ্যুয়াল বেসিক (ভিবি) তে কমান্ডটি ব্যবহার করুন :

Function beepNow()
Beep 
End Function

ভিবি কোডিং পেতে, আপনাকে Developer tabউপলব্ধ হওয়া দরকার (দেখুন: বিকাশকারী ট্যাবটি দৃশ্যমান করা )

সুতরাং আপনার যখন কোনও ঘরে বা অবস্থার পরিবর্তন হবে, তখন এটি বীপ হবে। উপরের ভিবিএস কোডটিতে কল করার জন্য ম্যাক্রোর উদাহরণ:=IF(C2<>C3,beepNow(),"")

— BlizzardsGambit
সূত্র

2

কেবল সচেতন হন যে আপনি যদি বর্তমানে কোনও ভিবিএ ইউডিএফ ব্যবহার না করেন তবে তাদের পরিচয় করিয়ে দেওয়ার ফলে একটি বিশাল কর্মক্ষমতা হ্রাস পেতে পারে (যেমন সাধারণ ফাংশনগুলির বিপরীতে, তারা কেবলমাত্র মূল থ্রেডে চালিত হয়)। একটি একক বীপের সমস্যা হওয়া উচিত নয়, তবে আপনি যদি এটিকে ছড়িয়ে ছিটিয়ে শুরু করেন তবে আপনার সমস্যা হবে।

— সাপি

1

দুর্ভাগ্যক্রমে এই ফাংশনটি আপনার পিসি স্পিকার ব্যবহার করে - আপনার সাউন্ড কার্ড এবং স্পিকার নয়, অভ্যন্তরীণ স্পিকার। এফওয়াইআই - অনেক সংস্থায় পিসি স্পিকারটি সরিয়ে দেওয়া বা অক্ষম করা হয়েছে যাতে আপনি কিছু শুনতে পাবেন না।

— রাদেবাস

1

বিকল্প হিসাবে এসএসে মডিউল স্থাপনের জন্য, আপনি এটি আপনার ব্যক্তিগত.এক্সএলএসবিতে রাখতে পারেন। এটি আপনাকে যে কোনও এসএসের জন্য "বীপ" উপলভ্য করতে সক্ষম করবে। এটি চালাতে, হয় দ্রুত অ্যাক্সেস সরঞ্জামদণ্ডটি সংশোধন করুন বা আপনার এস-এস-এ ক্লিক করতে একটি বোতাম / আকৃতি সন্নিবেশ করুন এবং এতে ম্যাক্রো নির্ধারণ করুন।

— রুথি
সূত্র

সুপার ব্যবহারকারীকে স্বাগতম এটি অন্যান্য উত্তরগুলিতে একটি পৃথক পৃথক সমাধানের পরিবর্তে একটি মন্তব্য বলে মনে হয়, যা উত্তর পোস্টগুলির উদ্দেশ্যে। আরও কিছুটা প্রতিনিধির সাথে আপনি মন্তব্য পোস্ট করতে সক্ষম হবেন।

— ফিক্সার 1234

0

@ Ƭᴇcʜιᴇ007 দ্বারা পোস্ট করা উত্তরটি একটি ব্যতিক্রম সহ অন্যদের দ্বারা মন্তব্য করা একটি দুর্দান্ত উত্তর: Beepপদ্ধতিটি কম্পিউটারের মধ্যে আপনার বোর্ডের (এবং কখনও কখনও অক্ষম) স্পিকারের উপর নির্ভর করে এবং আপনার স্পিকার ব্যবহার করে না, তাই আপনি কিছুই শুনতে পাচ্ছেন না।

আমি সেই উত্তরের ভিত্তিতে একটি পোস্ট পোস্ট করছি। যদি কম লিখিত বিষয়বস্তু থাকত তবে আমি তার পরিবর্তে একটি মন্তব্য পোস্ট করতাম।

উইন্ডোতে ভিবিএর সাথে আমি শব্দটি খেলতে যা ব্যবহার করি তা এখানে। এটি আপনার সাধারণ কম্পিউটার স্পিকারটি অনবোর্ডের পরিবর্তে ব্যবহার করে এবং প্রায়শই অক্ষম স্পিকারটিকে Beepপদ্ধতিটি অ্যাক্সেস করে ।

উত্তরটি @ @cʜιᴇ007 দ্বারা শুরু করুন। কেবল এটিতে পরিবর্তন Beepকরুন:

PlaySound sound_Up

আপনি পরিবর্তন করে শব্দ পরিবর্তন করতে পারেন sound_Upহিসাবে যেমন নিচের কোডে SoundType শুমার (তালিকা) থেকে অন্য আইটেমে sound_Completeবা sound_Notify।

Option Explicit
' --------------------------------------------------
' --------------------------------------------------
'   REQUIRED DLL REFERENCE AND CONSTANTS
' --------------------------------------------------
' Reference to external procedure in DLL to play sounds

#If VBA7 Then
    ' 64-bit MS Office
    Private Declare PtrSafe Function sndPlaySound32bit Lib "winmm.dll" Alias "sndPlaySoundA" (ByVal lpszSoundName As String, ByVal uFlags As LongPtr) As LongPtr
#Else
    ' 32-bit MS Office
    Private Declare Function sndPlaySound32bit Lib "winmm.dll" Alias "sndPlaySoundA" (ByVal lpszSoundName As String, ByVal uFlags As LongPtr) As LongPtr
#End If

' --------------------------------------------------
' --------------------------------------------------
'   CONSTANTS
' --------------------------------------------------
'
Public Const SOUND_DO_NOT_WAIT          As String = "&H1"
Private Const SOUND_FILES_PATH          As String = "C:\Windows\Media\"

' --------------------------------------------------
' --------------------------------------------------
'   PUBLIC ENUMERATIONS
' --------------------------------------------------
'
Public Enum SoundType
    sound_None = 0
    sound_Up = 1
    sound_Down = 2
    sound_Attention = 3
    sound_Blocked = 4
    sound_Boop = 5
    sound_Complete = 6
    sound_Critical = 7
    sound_Ding = 8
    sound_Error = 9
    sound_Exclamation = 10
    sound_FastDown = 11
    sound_Information = 12
    sound_Notify = 13
    sound_PhoneRing = 14
    sound_RingOut = 15
    sound_Stop = 16
    sound_Tada = 17
    sound_Tone = 18
End Enum

' --------------------------------------------------
' --------------------------------------------------
'   PUBLIC METHODS
' --------------------------------------------------
'
Public Sub PlaySound(ByVal sound As SoundType)
' Plays a sound from a list (see the 'SoundType' Enum).  Code execution continues
'   while sound is playing.
    Dim soundFileName                   As String
    soundFileName = GetSoundFileName(sound)

    If Not soundFileName = vbNullString Then
        sndPlaySound32bit SOUND_FILES_PATH & soundFileName, SOUND_DO_NOT_WAIT
    End If
End Sub

' --------------------------------------------------
' --------------------------------------------------
'   PRIVATE DEPENDENCIES
' --------------------------------------------------
'
Private Function GetSoundFileName(ByVal soundToGet As SoundType) As String
' Returns a windows sound file name (not path) from a member of the custom
'   'SoundType' enumeration.

    Dim fName                           As String

    Select Case soundToGet
    Case sound_Up:          fName = "Speech On.wav"
    Case sound_Down:        fName = "Speech Off.wav"
    Case sound_Attention:   fName = "Windows Battery Low.wav"
    Case sound_Blocked:     fName = "Windows Pop-up Blocked.wav"
    Case sound_Boop:        fName = "Speech Misrecognition.wav"
    Case sound_Complete:    fName = "Windows Print complete.wav"
    Case sound_Critical:    fName = "Windows Critical Stop.wav"
    Case sound_Ding:        fName = "Windows Ding.wav"
    Case sound_Error:       fName = "Windows Error.wav"
    Case sound_Exclamation: fName = "Windows Exclamation.wav"
    Case sound_FastDown:    fName = "Speech Sleep.wav"
    Case sound_Information: fName = "Windows Information Bar.wav"
    Case sound_Notify:      fName = "notify.wav"
    Case sound_PhoneRing:   fName = "Windows Ringin.wav"
    Case sound_RingOut:     fName = "Windows Ringout.wav"
    Case sound_Stop:        fName = "chord.wav"
    Case sound_Tada:        fName = "tada.wav"
    Case sound_Tone:        fName = "Windows Balloon.wav"
    Case Else:              fName = vbNullString
    End Select

    GetSoundFileName = fName
End Function

— ChrisB
সূত্র