মাসে রবিবারের সংখ্যা গণনা করুন

Question

মাইক্রোসফ্ট এক্সেলে আমি যে কোনও মাসে রবিবারের সংখ্যা নির্ধারণ করতে চাই। আমি বাজেটের স্প্রেডশিট একসাথে রাখছি এবং চারটি পরিবর্তে পাঁচ রবিবার মাসে থাকাকালীন উপ-অ্যাকাউন্টগুলির কিছু অতিরিক্ত ফান্ডিং পাবে।

আমার কেবলমাত্র সেই সেলটি উল্লেখ করা উচিত শীটটির শিরোনাম যা সেল এ 1 এ রয়েছে এবং এটি বর্তমান মাসের সমান। উদাহরণ স্বরূপ6/1/14

Answer 1

A1মাসের প্রথম দিনটি এখানে চেষ্টা করুন :

=SUMPRODUCT(N(TEXT(ROW(INDIRECT(A1&":"&EOMONTH(A1,0))),"ddd")="Sun"))

আপনি এটিকে সপ্তাহের যে কোনও দিন কেবল পরিবর্তন "Sun"এবং যে কোনও তারিখের সীমা A1শুরু করার তারিখ এবং EOMONTH(A1,0)শেষ তারিখের পরিবর্তে ব্যবহার করতে পারেন ।

Comments

কি দারুন. এটি সত্যিই সৃজনশীল। আমাকে বুঝতে দিন। আমরা পরোক্ষ এবং সারি ফাংশন দিয়ে পুরো মাসের জন্য তারিখ মান তৈরি করি? তারপরে আমরা এগুলিকে সূর্য, সোম ইত্যাদি আকারে পাঠ্যে রূপান্তর করি আমরা সূর্যের অবস্থার জন্য মূল্যায়ন করি এবং ফলাফলটিকে এক বা শূন্যে পরিবর্তন করি এবং তারপরে ফলাফলের যোগফল করি। এটা কি ঠিক?

— wbeard52

হ্যাঁ ঠিক .. :)

— জয়-আর

Answer 2

আপনি যে তারিখটির কথা উল্লেখ করেছেন তা যদি সর্বদা মাসের প্রথম হয় তবে এটিও কাজ করবে:

=INT((WEEKDAY(A1-1)+EOMONTH(A1,0)-A1)/7)

Comments

সহজ। আমার উপরের সূত্রটির তুলনায় খুব মার্জিত। ধন্যবাদ।

— wbeard52

Answer 3

পূর্ববর্তী উত্তরের সাথে খুব সমান, তবে কিছুটা ক্লিনার ...

=SUMPRODUCT(N(WEEKDAY(ROW(INDIRECT(A1&":"&EOMONTH(A1,0))))=1))

Answer 4

=DAY(EOMONTH(A1,0))-NETWORKDAYS.INTL(A1,EOMONTH(A1,0),11)

সম্পাদনা: এটি এক্সেল ২০১ works সালে কাজ করে, নেটওর্কেডেআইএস.আইএনটিএল কখন চালু হয়েছিল তা নিশ্চিত নয়।

Comments

নেটওয়ার্কডয়েস কী nt এটি সমস্ত

— এক্সেলের

আহ, আপনি ঠিক বলেছেন। আমি দেখতে পাইনি যে তিনি এক্সেল ২০১০-তে উল্লেখ করছেন। আমার কাছে ২০১ 2016 রয়েছে network নেটওয়ার্কের দিনগুলির চেয়ে আলাদা, নেটওয়ার্ক ডেডস.ইন্টল আপনাকে সাপ্তাহিক ছুটি বেছে নিতে দেয়। এই ক্ষেত্রে, আমি এক্সেলকে বলেছিলাম যে সপ্তাহান্তে কেবল রবিবার, 11 এটাই। সুতরাং এটি আপনাকে রবিবার গণনা না করে সময়ের মধ্যে সংখ্যা দেয়।

— এসআরসিপি

NETWORKDAYS.INTLএক্সেল 2010 থেকে পাওয়া যায় । আপনি এর নামের পাশে 2010 নম্বর দেখতে পারেন। এটির এক্সেল 2010 এ কাজ করার স্ক্রিনশটটি

— phuclv

Answer 5

আমি বিশ্বাস করি আমি এই বিড়ালের চামড়ার আরও একটি উপায় খুঁজে পেয়েছি (সুতরাং কথা বলার জন্য)।

যদি আপনি তারিখ প্রবেশ করা এড়াতে চান এবং প্রজেকশনটির জন্য একটি বড় চাদর (উদাহরণস্বরূপ 18 মাস আগে) থাকে তবে আপনি তার পরিবর্তে কেবল আপনার মাস এবং বছর কী সূত্রটি বলতে পারেন এবং সে অনুযায়ী ফর্ম্যাট করতে পারেন। এটি শিরোনামের কক্ষগুলির সাথে এক নিখুঁত রেফারেন্সের সাথে যোগ দিয়েছে যা সপ্তাহের দিনটি প্রশ্নে রয়েছে এবং আপনার কাছে আরও অনেক কমপ্যাক্ট এবং ক্লিনার টেবিল রয়েছে (আমার মতে)।

এ 3 = জানু, বি 3 = 2017, সি 2: আই 2 = 3 চার ডে সংক্ষিপ্তকরণ (অর্থাত্ এসইএন)

C3 ঘরে সূত্র প্রবেশ করান

=SUMPRODUCT(N(TEXT(ROW(INDIRECT(DATEVALUE(TEXT(CONCAT($A3,"/",$B3),"mm/dd/yyyy"))&":"&EOMONTH(DATEVALUE(TEXT(CONCAT($A3,"/",$B3),"mm/dd/yyyy")),0))),"ddd")=C$2))

শুভ শিকার

Answer 6

গৃহীত উত্তরের একটি সামান্য প্রকরণ , যেখানে আপনাকে মাসের প্রথম দিনের প্রয়োজন হবে না A1।

এটি প্রতিস্থাপনের A1মাধ্যমে অর্জন করা হয়:

date(year(today()),month(today()),1)

এটি ধরে নেওয়া হচ্ছে যে আপনি এটি চলতি মাসের জন্য চান।

=SUMPRODUCT(N(TEXT(ROW(INDIRECT(date(year(today()),month(today()),1)&":"&EOMONTH(date(year(today()),month(today()),1),0))),"ddd")="Sun"))