কী-বোর্ড শর্টকাট ব্যবহার করে এক্সেল সেলটি কীভাবে নির্বাচন করতে হবে?

14

কীবোর্ড শর্টকাট Ctrl+ ক্লিক করে একাধিক এক্সেল সেল নির্বাচন করা যায় (হয় স্বচ্ছন্দে বা না) Click

আপনি কীভাবে পূর্বে নির্বাচিত এই কোষগুলির এক বা একাধিকটি অনির্বাচিত করবেন?

microsoft-excel keyboard-shortcuts

5

শিফট এবং / অথবা সিটিআরএল কীগুলি ব্যবহার করে আপনি অ-স্বচ্ছল রেঞ্জ নির্বাচন করতে পারেন। তবে, আপনি যদি ভুল করে কোনও ঘর বা অঞ্চল নির্বাচন করেন তবে পুরো নির্বাচনটি না হারিয়ে এবং আবার শুরু না করেই নির্বাচন থেকে সেটি সরিয়ে নেওয়ার কোনও ভিত্তি নেই। এই পৃষ্ঠাটি ভিবিএ পদ্ধতিগুলি, আনসিলিটএ্যাকটিভসেল এবং আনসিলিটকন্ট্রেনিয়ারিয়া বর্ণনা করে যা বর্তমান নির্বাচন থেকে সক্রিয় সেল বা অ্যাক্টিভ সেল সম্বলিত অঞ্চলটি সরিয়ে দেবে। নির্বাচনের অন্যান্য সমস্ত কক্ষ নির্বাচিত থাকবে।

আপনার সেরা বাজি হ'ল এগুলি আপনার ব্যক্তিগত ম্যাক্রো ওয়ার্কবুকে যুক্ত করা যাতে তারা এক্সেলের সমস্ত ওপেন ওয়ার্কবুকগুলিতে উপলব্ধ।

এই পদ্ধতিটি নির্বাচন থেকে সক্রিয় সেলটি সরিয়ে ফেলবে ।

Sub UnSelectActiveCell()
    Dim R As Range
    Dim RR As Range
    For Each R In Selection.Cells
        If StrComp(R.Address, ActiveCell.Address, vbBinaryCompare) <> 0 Then
            If RR Is Nothing Then
                Set RR = R
            Else
                Set RR = Application.Union(RR, R)
            End If
        End If
    Next R
    If Not RR Is Nothing Then
        RR.Select
    End If
End Sub

এই পদ্ধতিটি নির্বাচন থেকে সক্রিয় সেলযুক্ত অঞ্চলটি সরিয়ে ফেলবে।

Sub UnSelectCurrentArea()
    Dim Area As Range
    Dim RR As Range

    For Each Area In Selection.Areas
        If Application.Intersect(Area, ActiveCell) Is Nothing Then
            If RR Is Nothing Then
                Set RR = Area
            Else
                Set RR = Application.Union(RR, Area)
            End If
        End If
    Next Area
    If Not RR Is Nothing Then
        RR.Select
    End If
End Sub

— শহরবাসী
সূত্র

1

আমি অবাক হয়েছি আপনি UnSelectActiveCellযদি রেঞ্জের সাথে মিল রেখে এবং কেবলমাত্র কোষগুলির মধ্য দিয়ে লুপ করেন তবে দ্রুত তৈরি করতে পারেন Not Intersect(Area,ActiveCell) Is Nothing। যদি Intersectফাংশনটি ফাংশনের চেয়ে এত ধীর StrCompহয় যে এটি কলগুলিতে হ্রাসকে অফসেট করতে পারে না তবে এটি ক্ষেত্রে হতে পারে না Union।

— ইঞ্জিনিয়ার টোস্ট

1

— Excelশ্বর

এটা কি এখনও আছে? আমি আমার জীবনের জন্য deselectএকটি ঘর কীভাবে তা জানতে পারি না । একেবারেই হাস্যকর! আমি প্রতি 2 র্থ কলামটি নির্বাচন করছি এবং যদি আমার কোনও ভুল হয় তবে আমার অবশ্যই শুরু করা উচিত? এটি% & * পাগল!

— পুকি

2

একাধিক কক্ষগুলি অনির্বাচিত করার আরও শক্তিশালী উপায়টি এই এক্সটেনডঅফিস নিবন্ধে বর্ণিত হয়েছে । এটিতে একটি অতিরিক্ত প্রম্পট অন্তর্ভুক্ত রয়েছে তবে আপনি একবারে একটি স্বেচ্ছাসেবী কোষ / নির্বাচনগুলি অনির্বাচিত করতে পারেন (কেবলমাত্র সক্রিয় ঘর বা অঞ্চলটি নির্বাচন না করে)

আমি এখানে স্ক্রিপ্টটি সামান্য ব্যবহারযোগ্যতার উন্নতি সহ পোস্ট করছি (শর্তাধীন মূল পোস্ট থেকে অপ্রয়োজনীয় প্রথম প্রম্পটটি সরিয়ে নিয়েছে):

Sub DeselectCells()
    Dim rng As Range
    Dim InputRng As Range
    Dim DeleteRng As Range
    Dim result As Range
    xTitleId = "Deselect Cells"

    Set InputRng = Application.Selection
    If InputRng.Count <= 1 Then
        Set InputRng = Application.InputBox("Range :", xTitleId, InputRng.Address, Type:=8)
    End If
    Set DeleteRng = Application.InputBox("Delete Range", xTitleId, Type:=8)
    For Each rng In InputRng
        If Application.Intersect(rng, DeleteRng) Is Nothing Then
            If result Is Nothing Then
                Set result = rng
            Else
                Set result = Application.Union(result, rng)
            End If
        End If
    Next
    result.Select
End Sub

এটি ব্যবহার করার জন্য, আপনাকে একটি নির্বাচন করুন, ডাকা DeselectCellsহতে পারে ম্যাক্রো (যা আপনার ব্যক্তিগত ম্যাক্রো বইয়ে সংরক্ষিত এবং একটি শর্টকাট নির্ধারিত করা হয়) এবং কক্ষ নির্বাচন করতে ডি পপআপ নির্বাচিত প্রদর্শিত:

— জিওভান্নি
সূত্র

দুর্দান্ত সন্ধান, দুর্দান্ত উত্তর।

— বুর্গি

1

ভুল করে নির্বাচিত একটি সেল সিটিআরএলে নির্বাচন করা এখন সম্ভব। এটি অফিস 365 বা সাম্প্রতিক সংস্করণগুলিতে কার্যকরী একটি নতুন অন্তর্নির্মিত। অবশেষে!

— স্টিভ
সূত্র