খালি লাইনে zsh ট্যাব সমাপ্তি

Question

আমি এমন একটি tc''ism চাই যা আমি খুঁজে পাইনি: কোনও লিখিত সামগ্রী ছাড়াই ফাঁকা লাইনে আমি ট্যাব কী টিপতে চাই এবং একটি এলএস এর সমতুল্য দেখতে চাই। বলতে চাই আমি চাই

$ <tab>

অন্য কিছু করার জন্য আমাকে একটি giving t দেয়। কমান্ড সমাপ্তির জন্য আমি দুর্দান্ত উত্স পেয়েছি, তবে এই বেস কেসের জন্য নয়। এ সম্পর্কে কোনও সহায়তা দুর্দান্ত হবে! ধন্যবাদ।

Answer 1

# expand-or-complete-or-list-files
function expand-or-complete-or-list-files() {
    if [[ $#BUFFER == 0 ]]; then
        BUFFER="ls "
        CURSOR=3
        zle list-choices
        zle backward-kill-word
    else
        zle expand-or-complete
    fi
}
zle -N expand-or-complete-or-list-files
# bind to tab
bindkey '^I' expand-or-complete-or-list-files

Comments

খুব ঝরঝরে. আবার কি কোনওভাবে তালিকাটি লুকিয়ে রাখা সম্ভব হবে? ট্যাব-টু-শো তখন ট্যাব-থেকে-লুকানো ভাল লাগবে।

— পার্কার কোটস

ধন্যবাদ জন, আমি আপনার সমাধান পাওয়া যায় এবং এখানে অভিযোজিত stackoverflow.com/questions/28729851/...

— lolesque

Answer 2

Tabএকটি লাইনের শুরুতে আচরণ স্টাইল দ্বারা নিয়ন্ত্রিত হয় । তবে কেবল দুটি সমর্থিত আচরণ রয়েছে:insert-tab

• যথারীতি সম্পূর্ণ, অধীন zstyle ':completion:*' insert-tab false
• এর অধীনে একটি ট্যাব sertোকান zstyle ':completion:*' insert-tab true
• এক বা অন্য অধীনে zstyle ':completion:*' insert-tab pending[=N]

আপনি যদি কেবলমাত্র সেই অবস্থানে কমান্ডগুলি সম্পূর্ণ করতে চান zstyle ':completion:*' insert-tab trueতবে করবেন। আপনি যদি বর্তমান ডিরেক্টরিতে ফাইল তালিকাভুক্ত করার মতো কিছু আলাদা করতে চান তবে আপনাকে সংশোধন করতে হবে _main_complete।

Zsh- কর্মীদের তালিকার একটি সাম্প্রতিক থ্রেড আলোচিত insert-tab।

Comments

চমত্কার! _মেন_কম্পল করে দেখে মনে হচ্ছে আপনি সি কোডের কোথাও উল্লেখ করছেন? আমি বোবা প্রশ্নের জন্য দুঃখিত, তবে কোথায় পাওয়া যাবে?

@ user535759: না, _main_completezsh কোডের অংশ যা সম্পূর্ণকরণ কার্যকর করে। এটি Completion/Base/Core/_main_completeউত্স ট্রিতে রয়েছে, সাধারণত কোনও জায়গায় ইনস্টল /usr/share/zsh/functions/Completion/Base/_main_complete।

— গিলস 'অশুভ হওয়া বন্ধ করুন' 31:12

@ লুলুয়া সম্পর্কিত স্টাইল পরিবর্তন করা -command-<< ট্যাব> বর্তমান ডিরেক্টরিতে ফাইল তালিকাবদ্ধ করে না। আপনি যা করেছেন তা হ'ল কমান্ডের নাম বাদ দেওয়ার জন্য ম্যাচগুলিকে সীমাবদ্ধ করা । কিন্তু যে জিনিস এই অবস্থানে সম্পন্ন করা হবে তালিকাভুক্ত করা হয় যাতে না (শুধুমাত্র ডিরেক্টরি এবং এক্সেকিউটেবল উপর নির্ভর করে বর্তমান ডিরেক্টরির সকল ফাইলের autocdএবং PATH)।

— গিলস 'অসন্তুষ্ট হওয়া বন্ধ করুন'

Answer 3

আপনি খালি লাইনে ট্যাব টিপলে zsh এ tcsh এর অটোলিস্টের সম্পূর্ণ প্রয়োগ রয়েছে

% <TAB>

এটা এখানে:

# list dir with TAB, when there are only spaces/no text before cursor,
# or complete words, that are before cursor only (like in tcsh)
tcsh_autolist() { if [[ -z ${LBUFFER// } ]]
    then BUFFER="ls " CURSOR=3 zle list-choices
    else zle expand-or-complete-prefix; fi }
zle -N tcsh_autolist
bindkey '^I' tcsh_autolist

আপনি যদি আরও কাছাকাছি tcsh অনুকরণ করতে চান, এটি আপনার .zshrc এ যুক্ত করুন:

unsetopt always_last_prompt       # print completion suggestions above prompt

Answer 4

আমি এই zsh উইজেটটি লিখেছি যা কেবলমাত্র একটি ফাঁকা লাইনে নয়, আপনি কমান্ডটি টাইপ করার সময়ও টিএবির ব্যবহার বাড়ায়।

• এটি খালি কমান্ড লাইনে এবং যে কোনও কমান্ডের মাঝখানে ফাইলগুলি তালিকাভুক্ত করবে ।
• এটি একটি খালি কমান্ড লাইনে ডিরেক্টরিগুলি তালিকাভুক্ত করবে ।
• এটি খালি কমান্ড লাইনে এক্সিকিউটেবলের তালিকাভুক্ত করবে ।

এটি বৈশ্বিক চলকযুক্ত ক্ষেত্রে "সিডি" বা "./" প্রিপেন্ড করতে কনফিগার করা যেতে পারে।

export TAB_LIST_FILES_PREFIX

# List files in zsh with <TAB>
#
# Copyleft 2017 by Ignacio Nunez Hernanz <nacho _a_t_ ownyourbits _d_o_t_ com>
# GPL licensed (see end of file) * Use at your own risk!
#
# Usage:
#   In the middle of the command line:
#     (command being typed)<TAB>(resume typing)
#
#   At the beginning of the command line:
#     <SPACE><TAB>
#     <SPACE><SPACE><TAB>
#
# Notes:
#   This does not affect other completions
#   If you want 'cd ' or './' to be prepended, write in your .zshrc 'export TAB_LIST_FILES_PREFIX'
#   I recommend to complement this with push-line-or edit (bindkey '^q' push-line-or-edit)
function tab_list_files
{
  if [[ $#BUFFER == 0 ]]; then
    BUFFER="ls "
    CURSOR=3
    zle list-choices
    zle backward-kill-word
  elif [[ $BUFFER =~ ^[[:space:]][[:space:]].*$ ]]; then
    BUFFER="./"
    CURSOR=2
    zle list-choices
    [ -z ${TAB_LIST_FILES_PREFIX+x} ] && BUFFER="  " CURSOR=2
  elif [[ $BUFFER =~ ^[[:space:]]*$ ]]; then
    BUFFER="cd "
    CURSOR=3
    zle list-choices
    [ -z ${TAB_LIST_FILES_PREFIX+x} ] && BUFFER=" " CURSOR=1
  else
    BUFFER_=$BUFFER
    CURSOR_=$CURSOR
    zle expand-or-complete || zle expand-or-complete || {
      BUFFER="ls "
      CURSOR=3
      zle list-choices
      BUFFER=$BUFFER_
      CURSOR=$CURSOR_
    }
  fi
}
zle -N tab_list_files
bindkey '^I' tab_list_files

# uncomment the following line to prefix 'cd ' and './' 
# when listing dirs and executables respectively
#export TAB_LIST_FILES_PREFIX

# these two lines are usually included by oh-my-zsh, but just in case
autoload -Uz compinit
compinit

# uncomment the following line to complement tab_list_files with ^q
#bindkey '^q' push-line-or-edit

# License
#
# This script is free software; you can redistribute it and/or modify it
# under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This script is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this script; if not, write to the
# Free Software Foundation, Inc., 59 Temple Place, Suite 330,
# Boston, MA  02111-1307  USA