গুগল QUERY এর মাধ্যমে কীভাবে DISTINCT / UNIQUE পাঠ্যের তালিকা ফিরিয়ে আনবেন?

Question

বিভাগ এবং উপ-বিভাগগুলির তালিকা দেওয়া হয়েছে:

CatA    SubCatA
CatA    SubCatA
CatB    SubCatB
CatB    SubCatB
CatC    SubCatC
CatC    SubCatC

আমি মাধ্যমিক বিভাগের উপর ভিত্তি করে সমস্ত অনন্য প্রধান বিভাগ ফিরে আসতে চাই।

আমি ব্যবহার করতে চাই না:

=QUERY(A1:B6,"SELECT A WHERE B = 'SubCatA'")

যেহেতু এটি অনুলিপি সহ তালিকাটি ফিরিয়ে দিচ্ছে (প্রথম উপাদানটি ফিরে আসা কোনওরকম কাজে আসবে না)।

আমি যা চেষ্টা করছি তা হ'ল:

=QUERY(A1:B6,"SELECT A WHERE B = 'SubCatA' GROUP BY A")

তবে এটি আমাকে ত্রুটি দেয়: CANNOT_GROUP_WITHOUT_AGGঅতএব, আমি উভয়ের DISTINCT(A)বা তার সমতুল্য কিছু সন্ধান করার চেষ্টা করছি UNIQUE(A)তবে এই ফাংশনগুলির অস্তিত্ব নেই।

গুগল ভিজ্যুয়ালাইজেশন এপিআই ক্যোরি ল্যাঙ্গুয়েজে অনন্য মানগুলির তালিকা ফিরিয়ে আনতে DISTINCT / UNIQUE এর সমতুল্য কোনও ফাংশন রয়েছে?

Answer 1

কোনও প্রশ্ন ছাড়াই:

=unique(filter(A1:A6, B1:B6="SubCatA"))

Comments

সহজ সমাধান।

— ওমিড

Answer 2

QUERYসূত্রের মধ্যে আপনাকে কোনও সহায়ক কলাম যুক্ত করতে হবে :

=QUERY(
   {A1:B6, A1:A6},
   "SELECT Col1, COUNT(Col3) WHERE Col2 = 'SubCatA' GROUP BY Col1 LABEL COUNT(Col3) ''"
 )

অন্য QUERYসূত্র যুক্ত করা সাহায্যকারী কলামটি সরিয়ে ফেলতে সহায়তা করবে:

=QUERY(
   QUERY(
     {A1:B6, A1:A6},
     "SELECT Col1, COUNT(Col3) WHERE Col2 = 'SubCatA' GROUP BY Col1"
   ), 
   "SELECT Col1"
 )

Answer 3

ফিল্টারটির আশেপাশে সর্বদা কার্যকর ইউনিক ফাংশনটি ব্যবহার করার পাশাপাশি user79865, আপনি পরামর্শ দিচ্ছেন যে আপনি মূল QUERY ফাংশনটির আশেপাশে ইউনিক্যু ব্যবহার করতে পারেন (যা ফিল্টার পর্যাপ্ত নয় যখন QUERY এর বিকল্প এবং নমনীয়তা সংরক্ষণের জন্য অন্যান্য পরিস্থিতিতে আরও প্রয়োগযোগ্য এবং সহায়ক হতে পারে) )।

তাই ভালো: =UNIQUE(QUERY(A1:B6,"SELECT A WHERE B = 'SubCatA'"))

Answer 4

সাহায্যকারী / মোড়ক কার্যবিহীন সমাধান:

=QUERY(A1:B6,"SELECT MAX(A) WHERE B = 'SubCatA' GROUP BY A LABEL MAX(A) ''")

Answer 5

Unique(range)ফাংশনটি ব্যবহার করুন ।

উদাহরণ:

=unique(query(Sheet2!A3:F2372,"SELECT C WHERE A contains '" &E1& "' AND B CONTAINS '" &E2& "'  ",-1))

এটি একটি কলাম পুনরুদ্ধারে কাজ করবে। আপনার টাস্কটি আরও অন্বেষণ করার জন্য আপনি এই কৌশলটি ব্যবহার করতে পারেন। এটি সহজ। A, B, C শীট 2 থেকে কলাম এবং E1, E2 বর্তমান ওয়ার্কশিট থেকে & এর সাথে ঘিরে রয়েছে।

Answer 6

ওপি বিশেষত গুগল QUERY এর মাধ্যমে জানতে চেয়েছে তবে এর উদাহরণ রয়েছে যে অন্য একটিতে একটি QUERY এবং আইএমওর জন্য আরও ভাল সমাধানের প্রয়োজন হয় না (কারণ আরও বিস্তৃত, এবং বহুমুখী) একটি পিভট টেবিল প্রয়োগ করতে হবে:

এই (এবং অন্যান্য হিসাবে) সমাধানের আরও ভাল প্রদর্শিত হবে যদি ডেটা নমুনা আরও বাস্তববাদী হয়।

Answer 7

কীভাবে ঠিক:

= UNIQUE(A1:B6)