এই প্রক্রিয়াটি আমি ব্যবহার করে শেষ করেছি। আমার ব্যবহৃত প্রধান সরঞ্জামটি ছিল ইনস্কেপ যা পাঠ্যকে ঠিকঠাক রূপান্তর করতে সক্ষম হয়েছিল।
- জাভাস্ক্রিপ্টের সাথে অ্যাডোব অ্যাক্রোব্যাট প্রো ক্রিয়াকলাপগুলি পিডিএফ শিটগুলিকে বিভক্ত করতে ব্যবহার করেছে
- উইন্ডোজ সিএমডি থেকে এসভিজিতে রূপান্তর করতে ইনস্কেপ পোর্টেবল 0.48.5 চালিয়েছে
- উইন্ডোজ সিএমডি এবং উইন্ডোজ পাওয়ারশেল ব্যবহার করে আমার কোনও সমস্যা হচ্ছিল একটি নির্দিষ্ট এসভিজি এক্সএমএল বৈশিষ্ট্যে কিছু ম্যানুয়াল সম্পাদনা করেছে
পৃথক পৃষ্ঠা: জাভাস্ক্রিপ্ট সহ অ্যাডোব অ্যাক্রোব্যাট প্রো
অ্যাডোব অ্যাক্রোব্যাট প্রো অ্যাকশন ব্যবহার করে (পূর্বে ব্যাচ প্রসেসিং) পিডিএফ পৃষ্ঠাগুলিকে পৃথক ফাইলে আলাদা করার জন্য একটি কাস্টম অ্যাকশন তৈরি করুন। বিকল্পভাবে আপনি ঘোস্টস্ক্রিপ্টের সাহায্যে পিডিএফ বিভক্ত করতে সক্ষম হতে পারেন
পৃষ্ঠাগুলি বিভক্ত করার জন্য অ্যাক্রোব্যাট জাভাস্ক্রিপ্ট ক্রিয়া
/* Extract Pages to Folder */
var re = /.*\/|\.pdf$/ig;
var filename = this.path.replace(re,"");
{
for ( var i = 0; i < this.numPages; i++ )
this.extractPages
({
nStart: i,
nEnd: i,
cPath : filename + "_s" + ("000000" + (i+1)).slice (-3) + ".pdf"
});
};
পিডিএফ থেকে এসভিজি রূপান্তর: উইন্ডোজ সিএমডি ব্যাচ ফাইলের সাথে ইনস্কেপ
একটি ফোল্ডারে সমস্ত পিডিএফ ফাইল লুপ করতে এবং সেগুলিকে এসভিজিতে রূপান্তর করতে উইন্ডোজ সিএমডি তৈরি ব্যাচ ফাইলটি ব্যবহার করে
বর্তমান ফোল্ডারে পিডিএফকে এসভিজিতে রূপান্তর করতে ব্যাচ ফাইল
:: ===== SETUP =====
@echo off
CLS
echo Starting SVG conversion...
echo.
:: setup working directory (if different)
REM set "_work_dir=%~dp0"
set "_work_dir=%CD%"
:: setup counter
set "count=1"
:: setup file search and save string
set "_work_x1=pdf"
set "_work_x2=svg"
set "_work_file_str=*.%_work_x1%"
:: setup inkscape commands
set "_inkscape_path=D:\InkscapePortable\App\Inkscape\"
set "_inkscape_cmd=%_inkscape_path%inkscape.exe"
:: ===== FIND FILES IN WORKING DIRECTORY =====
:: Output from DIR last element is single carriage return character.
:: Carriage return characters are directly removed after percent expansion,
:: but not with delayed expansion.
pushd "%_work_dir%"
FOR /f "tokens=*" %%A IN ('DIR /A:-D /O:N /B %_work_file_str%') DO (
CALL :subroutine "%%A"
)
popd
:: ===== CONVERT PDF TO SVG WITH INKSCAPE =====
:subroutine
echo.
IF NOT [%1]==[] (
echo %count%:%1
set /A count+=1
start "" /D "%_work_dir%" /W "%_inkscape_cmd%" --without-gui --file="%~n1.%_work_x1%" --export-dpi=300 --export-plain-svg="%~n1.%_work_x2%"
) ELSE (
echo End of output
)
echo.
GOTO :eof
:: ===== INKSCAPE REFERENCE =====
:: print inkscape help
REM "%_inkscape_cmd%" --help > "%~dp0\inkscape_help.txt"
REM "%_inkscape_cmd%" --verb-list > "%~dp0\inkscape_verb_list.txt"
ক্লিনআপ বৈশিষ্ট্য: উইন্ডোজ সিএমডি এবং পাওয়ারশেল
আমি বুঝতে পারি যে সম্ভাব্য প্রকরণের কারণে ম্যানুয়ালি জোর করে এসভিজি বা এক্সএমএল ট্যাগ বা বৈশিষ্ট্যগুলি সম্পাদন করা ভাল অনুশীলন নয় এবং এর পরিবর্তে একটি এক্সএমএল পার্সার ব্যবহার করা উচিত। তবে আমার একটি সাধারণ সমস্যা ছিল যেখানে একটি অঙ্কনের স্ট্রোকের প্রস্থ খুব কম ছিল এবং অন্যটিতে ফন্ট পরিবারটি ভুলভাবে চিহ্নিত করা হয়েছিল, তাই আমি সাধারণ অনুসন্ধান এবং প্রতিস্থাপনের জন্য মূলত পূর্ববর্তী উইন্ডোজ সিএমডি ব্যাচের স্ক্রিপ্টটি সংশোধন করেছি। কেবলমাত্র পরিবর্তনগুলি ছিল অনুসন্ধানের স্ট্রিং সংজ্ঞা এবং পাওয়ারশেল কমান্ডকে কল করতে পরিবর্তন করা। পাওয়ারশেল কমান্ডটি একটি যুক্ত প্রত্যয় সহ পরিবর্তিত ফাইলটি সন্ধান এবং প্রতিস্থাপন এবং সংরক্ষণ করবে। আমি অন্য কিছু উল্লেখ খুঁজে পেয়েছি যা ফলাফল এসভিজি ফাইলগুলি পার্স করতে বা সংশোধন করতে আরও ভাল ব্যবহার করা যেতে পারে যদি অন্য কোনও ছোটখাটো সাফাইয়ের প্রয়োজন হয়।
ম্যানুয়ালি এসভিজি এক্সএমএল ডেটা সন্ধান এবং প্রতিস্থাপনের পরিবর্তনসমূহ
:: setup file search and save string
set "_work_x1=svg"
set "_work_x2=svg"
set "_work_s2=_mod"
set "_work_file_str=*.%_work_x1%"
powershell -Command "(Get-Content '%~n1.%_work_x1%') | ForEach-Object {$_ -replace 'stroke-width:0.06', 'stroke-width:1'} | ForEach-Object {$_ -replace 'font-family:Times Roman','font-family:Times New Roman'} | Set-Content '%~n1%_work_s2%.%_work_x2%'"
আশা করি এটি কারও সাহায্য করবে
তথ্যসূত্র
অ্যাডোব অ্যাক্রোব্যাট প্রো ক্রিয়া এবং পৃথক পৃষ্ঠাগুলির জাভাস্ক্রিপ্ট উল্লেখ
ঘোস্টস্ক্রিপ্ট পৃথক পৃষ্ঠাগুলি উল্লেখ
পিডিএফ থেকে এসভিজি রূপান্তরের জন্য ইনস্কেপ কমান্ড লাইন উল্লেখ
উইন্ডোজ সিএমডি ব্যাচ ফাইল স্ক্রিপ্ট উল্লেখ
এক্সএমএল ট্যাগ / বৈশিষ্ট্য প্রতিস্থাপন গবেষণা