একটি সাধারণীকরণীয় রৈখিক মডেলের অবশিষ্টাংশের প্রত্যাশিত বিতরণ কী?
উত্তর:
What is the expected distribution of residuals?
এটি মডেলের সাথে বিভিন্নভাবে পরিবর্তিত হয় যা সাধারণভাবে উত্তর দেওয়া অসম্ভব করে তোলে।
For example, should the residuals be distributed normally?
সাধারণত না, না।
জিএলএমগুলির রেসিডুয়ালগুলি ডিজাইনের আশেপাশে রয়েছে একটি সম্পূর্ণ কুটির শিল্প যা আরও বেশি প্রতিসম বা এমনকি প্রায় "সাধারণ" (যেমন গাউসিয়ান), যেমন পিয়ারসনের অবশিষ্টাংশ, আনসকম্বের অবশিষ্টাংশ, (অ্যাডজাস্ট) ডিভ্যান্সের অবশিষ্টাংশ ইত্যাদি example । হার্ডিন এবং জোসেফ এম হিলবে (2007) "জেনারালাইজড লিনিয়ার মডেলস এবং এক্সটেনশনস" দ্বিতীয় সংস্করণ। কলেজ স্টেশন, টিএক্স: স্টাটা প্রেস। যদি নির্ভরশীল ভেরিয়েবলটি বিচ্ছিন্ন হয় (একটি সূচক পরিবর্তনশীল বা একটি গণনা) তবে অবশেষে গাউসিয়ানদের প্রত্যাশিত বন্টন করা অবশ্যই খুব কঠিন।
আপনি যা করতে পারেন তা হল আপনার মডেলটি সত্য বলে অনুমানের অধীনে নতুন ডেটা সিমুলেট করা, সেই সিমুলেটেড ডেটা ব্যবহার করে আপনার মডেলটি অনুমান করুন এবং অবশিষ্টাংশগুলি গণনা করুন এবং তারপরে আপনার প্রকৃত অবশিষ্টাংশগুলি আপনার সিমুলেটেড অবশিষ্টাংশগুলির সাথে তুলনা করুন। স্টাটাতে আমি এটি এরকম করতাম:
sysuse nlsw88, clear
glm wage i.union grade c.ttl_exp##c.ttl_exp, link(log) family(poisson)
// collect which observations were used in estimation and the predicted mean
gen byte touse = e(sample)
predict double mu if touse
// predict residuals
predict resid if touse, anscombe
// prepare variables for plotting a cumulative distribution function
cumul resid, gen(c)
// collect the graph command in the local macro `graph'
local graph "twoway"
// create 19 simulations:
gen ysim = .
forvalues i = 1/19 {
replace ysim = rpoisson(mu) if touse
glm ysim i.union grade c.ttl_exp##c.ttl_exp, link(log) family(poisson)
predict resid`i' if touse, anscombe
cumul resid`i', gen(c`i')
local graph "`graph' line c`i' resid`i', sort lpattern(solid) lcolor(gs8) ||"
}
local graph "`graph' line c resid, sort lpattern(solid) lcolor(black) "
// display the graph
`graph' legend(order(20 "actual residuals" 1 "simulations"))
