মাইক্রোফেসেট বিআরডিএফ বাস্তবায়নের চেষ্টা করছে তবে আমার ফলাফলের চিত্রগুলি ভুল

Question

আমি মাইক্রোফেসেট বিআরডিএফ মডেলটি বাস্তবায়নের চেষ্টা করছি। আমি সেবাস্তিয়ান লেগার্ডের স্লাইডগুলি পড়ছি । আমি আমার কোডটিতে সূত্রগুলি প্রয়োগ করেছি তবে আমি মনে করি ফলাফলের চিত্রটি ভুল।

হলুদ পদার্থের মূল রঙ। স্পেকুলার রঙ সঠিকভাবে দেখতে লাল।

আমার কোড:

// Fragment Shader
#version 330 core

in vec3 Position;
in vec2 TexCoord0;
in vec3 Normal;
in vec3 Tangent;
out vec4 FinalColor;

uniform vec3 uCameraPosition; // init value: vec3(0, 0, 5)

#define PI 3.1415926f
#define EPSILON 10e-5f
#define saturate(value) clamp(value, 0.0f, 1.0f);

float BRDF_Lambert(float NdotL)
{
    return NdotL;
}

// Got these BRDF formulas Moving Frostbite to PBR slide by Sebastien Lagarde & Charles de Rousiers 
// http://www.frostbite.com/wp-content/uploads/2014/11/course_notes_moving_frostbite_to_pbr_v2.pdf
float BRDF_D_GGX(float NdotH, float Roughness)
{
    float Roughness2 = Roughness * Roughness;
    float f = (NdotH * Roughness2 - NdotH) * NdotH + 1.0f;
    return Roughness2 / (f * f + EPSILON);
}


float BRDF_F_FresnelSchlick(float LdotH, float F0)
{
    float f = F0 + (1.0f - F0) * pow((1.0f - LdotH), 5);
    return f;
}

float BRDF_G_SmithGGXCorrelated(float NdotL, float NdotV, float Roughness)
{
    float Roughness2 = Roughness * Roughness;
    float GV = NdotL * sqrt((-NdotV * Roughness2 + NdotV) * NdotV + Roughness2);
    float GL = NdotV * sqrt((-NdotL * Roughness2 + NdotL) * NdotL + Roughness2);

    return 0.5f / (GV + GL + EPSILON);
}

float BRDF_Specular(float NdotV, float NdotL, float NdotH, float LdotH, float Roughness, float F0)
{
    float D = BRDF_D_GGX(NdotH, Roughness);
    float F = BRDF_F_FresnelSchlick(LdotH, F0);
    float G = BRDF_G_SmithGGXCorrelated(NdotL, NdotV, Roughness);
    return (D * F * G) / PI;
}

void main()
{
    FinalColor = vec4(1.0f, 1.0f, 1.0f, 1.0f);
    vec4 BaseColor = vec4(1.0f, 1.0f, 0.0f, 1.0f);
    vec4 SpecularColor = vec4(1.0f, 0.0f, 0.0f, 1.0f);
    vec3 LightDirection = normalize(vec3(0, 4, 4));
    vec3 ViewDirection = normalize(Position - uCameraPosition);
    vec3 HalfVector = normalize(ViewDirection + LightDirection);
    float Roughness = 0.9f; // [0.04 - 0.1f] -> Dielectric, [0.7, 1.0f] -> Metallic

    float RefractiveIndex = 0.27049f; // RI for Gold materials. I got this from http://refractiveindex.info/
    float F0 = pow(((1.0f - RefractiveIndex) / (1.0f + RefractiveIndex)), 2);

    float NdotL = saturate(dot(LightDirection, Normal));
    float NdotV = abs(dot(ViewDirection, Normal)) + EPSILON; // Avoid artifact - Ref: SIGGRAPH14 - Moving Frosbite to PBR
    float LdotH = saturate(dot(LightDirection, HalfVector));
    float NdotH = saturate(dot(Normal, HalfVector));

    float DiffuseFactor = BRDF_Lambert(NdotL);
    float SpecularFactor = BRDF_Specular(NdotV, NdotL, NdotH, LdotH, Roughness, F0);

    FinalColor = BaseColor * DiffuseFactor + SpecularColor * SpecularFactor;
}

সম্পাদনা

রুক্ষতা = 0.2f;

রুক্ষতা = 0.04f;

Comments

আমি কোডটি খুব বেশি বিশদে দেখিনি, তবে চিত্রটি ঠিক আছে বলে মনে হচ্ছে। ফ্রেসেল এফেক্টটি একটি লাল রিং হিসাবে প্রদর্শিত হবে। রুক্ষতা এত বেশি (0.9) এর সাথে বোঝা যায় যে বাকী চিত্রটি বেশিরভাগ ক্ষেত্রে হলুদ (অর্থাত্ বেশিরভাগ বিচ্ছুরিত)। আপনি যদি রুক্ষতা কম করেন তবে আপনি একটি লাল

— বর্ণের

@ রিচিস্যামস আমি বিভিন্ন রুক্ষতার মানগুলির জন্য নতুন চিত্র যুক্ত করেছি তবে এখনও লাল চকচকে নমুনা হাইলাইট দেখতে পাচ্ছি না।

— hmkum

আপনার 2 য় এবং 3 য় চিত্রগুলিতে আপনার আসল চিত্রের তুলনায় সাধারণভাবে (হলুদ বিচ্ছুরিত অঞ্চলে) কম লাল রয়েছে বলে মনে হচ্ছে। এটি খুব স্পষ্ট নয় কারণ একটি হলুদ অঞ্চলে সামান্য লাল যুক্ত করা এটি একটি অনুরূপ রঙ ছেড়ে দেয় (কমলা-হলুদ পরিবর্তে হলুদ)। আপনি যদি উল্লেখযোগ্যভাবে হলুদ হ্রাস করেন তবে আপনি কি লাল বিতরণের আরও বিস্তারিত দেখতে পাচ্ছেন? সম্পূর্ণরূপে হলুদ ছাড়াই ভুল কী হচ্ছে তা সনাক্ত করতে সহায়তা করতে পারে।

— ট্রাইকোপলাক্স

@ থ্রিচোপ্লেক্স আমি হলুদ কমিয়ে দিয়েছি তবে আবার লাল বর্ণক দেখার কোনও উপায় নেই। আমি কেবল লাল রিং (ফ্রেসনাল) প্রভাব দেখছি। রুক্ষতার জন্য আমি কী মূল্য নির্ধারণ করি তা বিবেচনা করা যায় না আমি একটি পয়েন্টকে কেন্দ্র করে এমন নমুনা প্রভাব দেখতে পারি না।

— hmkum

প্রথমে এটি ব্যবহারের আগে সাধারণ ভেক্টরকে স্বাভাবিক করুন এবং দ্বিতীয়টি দেখুন দিকনির্দেশ হ'ল অবস্থান থেকে ক্যামেরায় বহির্গামী ভেক্টর: uCameraPosition - অবস্থান।

— এক্সপিকক্স

Answer 1

রিচিস্যামস, ট্রাইকোপ্লেক্স এবং এক্সপিকক্স দ্বারা সমস্যা স্থির। উত্তরের জন্য আপনাকে সবাইকে ধন্যবাদ।

আমি রুক্ষতা কম করি, উপাদানের রঙ পরিবর্তন করি এবং দিশা বিপরীত করি তবে অবশেষে আমি যথাযথ স্পেসুলার দেখতে শুরু করি :)।

স্থির কোড:

#version 330 core

in vec3 Position;
in vec2 TexCoord0;
in vec3 Normal;
in vec3 Tangent;
out vec4 FinalColor;

uniform vec3 uCameraPosition;

#define PI 3.1415926f
#define EPSILON 10e-5f
#define saturate(value) clamp(value, 0.0f, 1.0f);

float BRDF_Lambert(float NdotL)
{
    return NdotL;
}

// Got these BRDF formulas Moving Frostbite to PBR slide by Sebastien Lagarde & Charles de Rousiers 
// http://www.frostbite.com/wp-content/uploads/2014/11/course_notes_moving_frostbite_to_pbr_v2.pdf
float BRDF_D_GGX(float NdotH, float Roughness)
{
    float Roughness2 = Roughness * Roughness;
    float f = (NdotH * Roughness2 - NdotH) * NdotH + 1.0f;
    return Roughness2 / (f * f + EPSILON);
}


float BRDF_F_FresnelSchlick(float LdotH, float F0)
{
    float f = F0 + (1.0f - F0) * pow((1.0f - LdotH), 5);
    return f;
}

float BRDF_G_SmithGGXCorrelated(float NdotL, float NdotV, float Roughness)
{
    float Roughness2 = Roughness * Roughness;
    float GV = NdotL * sqrt((-NdotV * Roughness2 + NdotV) * NdotV + Roughness2);
    float GL = NdotV * sqrt((-NdotL * Roughness2 + NdotL) * NdotL + Roughness2);

    return 0.5f / (GV + GL + EPSILON);
}

float BRDF_Specular(float NdotV, float NdotL, float NdotH, float LdotH, float Roughness, float F0)
{
    float D = BRDF_D_GGX(NdotH, Roughness);
    float F = BRDF_F_FresnelSchlick(LdotH, F0);
    float G = BRDF_G_SmithGGXCorrelated(NdotL, NdotV, Roughness);
    return (D * F * G) / PI;
}

void main()
{
    vec3 normal = normalize(Normal);

    vec4 BaseColor = vec4(1.0f, 0.0f, 0.0f, 1.0f);
    vec4 SpecularColor = vec4(1.0f, 1.0f, 1.0f, 1.0f);

    vec3 LightDirection = normalize(vec3(0, 4, 4) - Position);
    vec3 ViewDirection = normalize(uCameraPosition - Position);
    vec3 HalfVector = normalize(ViewDirection + LightDirection);
    float Roughness = 0.04f;

    float RefractiveIndex = 0.24f; // RI for Gold materials. I got this from http://refractiveindex.info/
    float F0 = pow(((1.0f - RefractiveIndex) / (1.0f + RefractiveIndex)), 2);

    float NdotL = saturate(dot(LightDirection, normal));
    float NdotV = abs(dot(ViewDirection, normal)) + EPSILON; // Avoid artifact - Ref: SIGGRAPH14 - Moving Frosbite to PBR
    float LdotH = saturate(dot(LightDirection, HalfVector));
    float NdotH = saturate(dot(normal, HalfVector));

    float DiffuseFactor = BRDF_Lambert(NdotL);
    float SpecularFactor = 0.0f;
    if(DiffuseFactor > 0.0f)
    {
        SpecularFactor = BRDF_Specular(NdotV, NdotL, NdotH, LdotH, Roughness, F0);
    }
    FinalColor = BaseColor * DiffuseFactor + SpecularColor * SpecularFactor;
}

চূড়ান্ত চিত্র: